blob: b45c1fc3ae270042ecf21af91d6f4ded83cbbb9d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit toolchain-funcs
DESCRIPTION="A tool for linting and static analysis of Lua code"
HOMEPAGE="https://github.com/mpeterv/luacheck"
SRC_URI="https://github.com/mpeterv/luacheck/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc luajit test"
RDEPEND="
dev-lua/luafilesystem[luajit=]
!luajit? ( >=dev-lang/lua-5.1:= )
luajit? ( dev-lang/luajit:2 )"
DEPEND="${RDEPEND}
virtual/pkgconfig
doc? ( dev-python/sphinx )
test? ( dev-lua/busted )"
DOCS=( CHANGELOG.md README.md )
src_compile() {
if use doc; then
sphinx-build docsrc html || die
fi
}
src_test() {
busted -o gtest || die
}
src_install() {
local instdir
instdir="$($(tc-getPKG_CONFIG) --variable INSTALL_LMOD $(usex luajit 'luajit' 'lua'))"
insinto "${instdir#${EPREFIX}}"
doins -r src/luacheck
newbin bin/luacheck.lua luacheck
use doc && HTML_DOCS+=( html/. )
einstalldocs
}
|
GitWeb
