blob: d4b1683267dd26343f2c2b192fbc6c30abc7e9e2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit multiprocessing elisp-common
DESCRIPTION="A composable build system for OCaml"
HOMEPAGE="https://github.com/ocaml/dune"
SRC_URI="https://github.com/ocaml/dune/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
IUSE="emacs test"
RESTRICT="strip !test? ( test )"
RDEPEND="
>=dev-lang/ocaml-4.08:=
emacs? ( >=app-editors/emacs-23.1:* )
!<dev-ml/dune-configurator-3
"
DEPEND="
${RDEPEND}
dev-ml/findlib
test? (
dev-ml/core_bench
dev-ml/ppx_bench
dev-ml/ppx_expect
)
"
QA_FLAGS_IGNORED="usr/bin/dune"
BYTECOMPFLAGS="-L ${S}/editor-integration/emacs"
SITEFILE="50${PN}-gentoo.el"
src_prepare() {
default
# This allows `dune --version` to output the correct version instead of "n/a"
sed -i "/^(name dune)/a (version ${PV})" dune-project || die
# This enables dune-configurator to use the vendored csexp module
sed -i 's/stdune.csexp/dune-configurator.csexp/' vendor/csexp/src/dune \
|| die
}
src_configure() {
./configure \
--libdir="$(ocamlc -where)" \
--mandir="/usr/share/man" \
|| die
}
src_compile() {
ocaml bootstrap.ml -j $(makeopts_jobs) || die
./dune.exe build -p "${PN}",dune-configurator --profile dune-bootstrap \
-j $(makeopts_jobs) \
--display short || die
use emacs && elisp-compile editor-integration/emacs/*.el
}
src_install() {
./dune.exe install --destdir="${D}" --prefix=/usr/ \
--libdir=$(ocamlc -where) dune dune-configurator \
|| die
rm -r "${D}"/usr/doc/dune-configurator || die
dodir /usr/share/doc
mv "${D}"/usr/doc/dune \
"${D}"/usr/share/doc/${PF} || die
rmdir "${D}"/usr/doc || die
if use emacs ; then
elisp-install ${PN} editor-integration/emacs/*.el{,c}
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
fi
}
|
GitWeb