summaryrefslogtreecommitdiff
blob: 390df28bbaba19edc64b42801104ec2c0398389b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
PYTHON_COMPAT=( python3_{8..9} )
DISTUTILS_USE_SETUPTOOLS=bdepend

inherit distutils-r1

DESCRIPTION="A Python data analysis library that is optimized for humans instead of machines"
HOMEPAGE="https://github.com/wireservice/agate https://pypi.org/project/agate/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
	>=dev-python/pytimeparse-1.1.5[${PYTHON_USEDEP}]
	>=dev-python/parsedatetime-2.1[${PYTHON_USEDEP}]
	>=dev-python/Babel-2.0[${PYTHON_USEDEP}]
	>=dev-python/isodate-0.5.4[${PYTHON_USEDEP}]
	>=dev-python/pyicu-2.4.2[${PYTHON_USEDEP}]
	>=dev-python/python-slugify-1.2.1[${PYTHON_USEDEP}]
	>=dev-python/leather-0.3.2[${PYTHON_USEDEP}]
"
BDEPEND="test? ( >=dev-python/leather-0.3.2[xml,${PYTHON_USEDEP}] )"

distutils_enable_tests pytest

# @FUNCTION: pytest-expect-to-deselect
# @USAGE: readarray -t pytest_args < <(pytest-expect-to-deselect <<<PYTEST_EXPECT_CONTENT)
# @DESCRIPTION:
# Read a pytest-expect pytest --xfail-file file from stdin and write
# equivalent pytest --deselect arguments to stdout for consumption by
# readarray -t. The generated pytest --deselect arguments are appropriate
# for use as described here:
# https://dev.gentoo.org/~mgorny/python-guide/pytest.html#skipping-tests-based-on-paths-names
pytest-expect-to-deselect() {
	while read -r; do
		[[ ${REPLY} =~ ^[u]?\'([^\']*) ]] || continue
		printf -- '%s\n' --deselect "${BASH_REMATCH[1]}" || return
	done
}

python_test() {
	# test_cast_format_locale fails with "locale.Error: unsupported locale setting"
	# which appears to be triggered by these locale settings in the unit tests:
	#
	#   agate-1.6.2/tests/test_data_types.py:257:    def test_cast_format_locale(self):
	#   agate-1.6.2/tests/test_data_types.py-258-        date_type = Date(date_format='%d-%b-%Y', locale='de_DE')
	#   agate-1.6.2/tests/test_data_types.py:381:    def test_cast_format_locale(self):
	#   agate-1.6.2/tests/test_data_types.py-382-        date_type = DateTime(datetime_format='%Y-%m-%d %I:%M %p', locale='ko_KR')

	local -a pytest_args
	readarray -t pytest_args < <(pytest-expect-to-deselect <<<"
pytest-expect file v1
(3, 8, 10, 'final', 0)
u'tests/test_data_types.py::TestDate::test_cast_format_locale': FAIL
u'tests/test_data_types.py::TestDateTime::test_cast_format_locale': FAIL
")

	epytest "${pytest_args[@]}" || die
}