blob: 27a23caab640a642b08d2173602649ee9949c510 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1 flag-o-matic
DESCRIPTION="Library providing cryptographic recipes and primitives"
HOMEPAGE="https://github.com/pyca/cryptography/ https://pypi.python.org/pypi/cryptography/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="|| ( Apache-2.0 BSD )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
IUSE="libressl test"
# the openssl 1.0.2l-r1 needs to be updated again :(
# It'd theb be able to go into the || section again
#=dev-libs/openssl-1.0.2l-r1:0
# the following is the original section, disallowing bindist entirely
#!libressl? ( >=dev-libs/openssl-1.0.2:0=[-bindist(-)] )
RDEPEND="
!libressl? (
dev-libs/openssl:0= (
|| (
dev-libs/openssl:0[-bindist(-)]
>=dev-libs/openssl-1.1.0g-r1:0
)
)
)
libressl? ( dev-libs/libressl:0= )
$(python_gen_cond_dep '>=dev-python/cffi-1.7:=[${PYTHON_USEDEP}]' 'python*')
$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python2_7 pypy{,3})
>=dev-python/idna-2.1[${PYTHON_USEDEP}]
>=dev-python/asn1crypto-0.21.0[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
>=dev-python/six-1.4.1[${PYTHON_USEDEP}]
virtual/python-ipaddress[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}
>=dev-python/setuptools-1.0[${PYTHON_USEDEP}]
test? (
~dev-python/cryptography-vectors-${PV}[${PYTHON_USEDEP}]
dev-python/hypothesis[${PYTHON_USEDEP}]
dev-python/iso8601[${PYTHON_USEDEP}]
dev-python/pretend[${PYTHON_USEDEP}]
dev-python/pyasn1-modules[${PYTHON_USEDEP}]
>=dev-python/pytest-2.9.0[${PYTHON_USEDEP}]
dev-python/pytz[${PYTHON_USEDEP}]
)"
DOCS=( AUTHORS.rst CONTRIBUTING.rst README.rst )
PATCHES=(
"${FILESDIR}"/${PN}-2.1.4-libressl-2.7-x509.patch
"${FILESDIR}"/${PN}-2.1.4-libressl-2.7-x509_vfy.patch
)
python_configure_all() {
append-cflags $(test-flags-CC -pthread)
}
python_test() {
py.test -v -v -x || die "Tests fail with ${EPYTHON}"
}
|
GitWeb
