dev-python/distlib/distlib-0.3.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DISTUTILS_USE_SETUPTOOLS=no
PYTHON_COMPAT=( python3_{7..10} pypy3 )

inherit distutils-r1 vcs-snapshot

DESCRIPTION="Low-level components of distutils2/packaging"
HOMEPAGE="https://pypi.org/project/distlib/
	https://bitbucket.org/pypa/distlib/"
# pypi has zip only :-(
SRC_URI="
	https://bitbucket.org/pypa/distlib/get/${PV}.tar.bz2 -> ${P}.tar.bz2"

LICENSE="PSF-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
IUSE="test"
# This package's tests are extremely fragile and tend to break or hang
# when it doesn't like metadata of packages installed on the system.
RESTRICT="test"

# pypiserver is called as external executable
# openpyxl installs invalid metadata that breaks distlib
BDEPEND="
	test? (
		dev-python/pypiserver
		!!<dev-python/openpyxl-3.0.3[${PYTHON_USEDEP}]
	)"

src_prepare() {
	# make sure they're not used
	rm -r tests/unittest2 || die
	rm tests/pypi-server-standalone.py || die

	# use system pypiserver instead of broken bundled one
	eapply "${FILESDIR}"/distlib-0.3.2-system-pypiserver.py || die
	# fix tests for py310
	eapply "${FILESDIR}"/${P}-py310.patch

	# doesn't work with our patched pip
	sed -e '/PIP_AVAIL/s:True:False:' \
		-i tests/test_wheel.py || die

	distutils-r1_src_prepare
}

python_test() {
	local -x SKIP_ONLINE=1
	local -x PYTHONHASHSEED=0
	"${EPYTHON}" tests/test_all.py -v -x ||
		die "Tests failed with ${EPYTHON}"
}