summaryrefslogtreecommitdiff
blob: 3ac269bd7231f9d9656aebef2a3589896b49ec48 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{6..9} )
inherit distutils-r1

DESCRIPTION="Fake implementation of redis API for testing purposes"
HOMEPAGE="
	https://github.com/jamesls/fakeredis/
	https://pypi.org/project/fakeredis/"
SRC_URI="
	https://github.com/jamesls/fakeredis/archive/${PV}.tar.gz
		-> ${P}.gh.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"

RDEPEND="
	dev-python/redis-py[${PYTHON_USEDEP}]
	dev-python/six[${PYTHON_USEDEP}]
	dev-python/sortedcontainers[${PYTHON_USEDEP}]"

distutils_enable_tests pytest

python_test() {
	local excludes=(
		# tests for use with aioredis, not packaged in ::gentoo
		--ignore test/test_aioredis.py
		# tests requiring lupa (lua support)
		-k 'not test_eval and not test_lua and not test_script'
	)

	pytest -vv "${excludes[@]}" || die "Tests failed with ${EPYTHON}"
}