summaryrefslogtreecommitdiff
blob: d1c230c8a53f9c9de3771784a805b99231dc1899 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Copyright 2020-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1

DESCRIPTION="Robust and reusable Executor for joblib"
HOMEPAGE="https://github.com/joblib/loky"
SRC_URI="
	https://github.com/joblib/loky/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"

RDEPEND="
	dev-python/cloudpickle[${PYTHON_USEDEP}]
	dev-python/psutil[${PYTHON_USEDEP}]"
BDEPEND="
	test? (
		dev-python/numpy[${PYTHON_USEDEP}]
	)"

distutils_enable_tests pytest

python_test() {
	local args=(
		# docker, seriously?
		--deselect 'tests/test_loky_module.py::test_cpu_count_cfs_limit'
		# hangs, and even pytest-timeout does not help
		--deselect 'tests/test_reusable_executor.py::TestExecutorDeadLock::test_deadlock_kill'
		# one test that uses a lot of memory, also broken on 32-bit
		# platforms
		--skip-high-memory
		# breaks teardown
		-p no:xvfb
	)

	epytest "${args[@]}"
}