dev-python/mapbox-vector-tile/mapbox-vector-tile-2.1.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Copyright 2023-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=poetry
PYTHON_COMPAT=( python3_{10..12} )

inherit distutils-r1

DESCRIPTION="Mapbox Vector Tile encoding and decoding."
HOMEPAGE="
	https://github.com/tilezen/mapbox-vector-tile/
	https://pypi.org/project/mapbox-vector-tile/
"
SRC_URI="https://github.com/tilezen/mapbox-vector-tile/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 arm64 ~x86"

RDEPEND="
	dev-python/protobuf[${PYTHON_USEDEP}]
	>=dev-python/pyclipper-1.3.0[${PYTHON_USEDEP}]
	>=dev-python/pyproj-3.4.1[${PYTHON_USEDEP}]
	>=dev-python/shapely-2.0.0[${PYTHON_USEDEP}]
"

distutils_enable_tests unittest

src_prepare() {
	# don't install into top-level
	sed -Ei '/include = \[/,/\]/ { /(README|CHANGELOG)/d }' pyproject.toml || die
	# relax the dep
	sed -i -e '/protobuf/s:\^[0-9.]*:*:' pyproject.toml || die
	distutils-r1_src_prepare
}