blob: 56c76f32f784642f3803c0ccd4cc5462cb282898 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
PYTHON_REQ_USE="ssl(+)"
inherit distutils-r1
DESCRIPTION="Python FTP server library"
HOMEPAGE="https://github.com/giampaolo/pyftpdlib https://pypi.org/project/pyftpdlib/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ia64 ~m68k ~mips ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris"
IUSE="doc examples ssl test"
RDEPEND="
ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
"
DEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
doc? (
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
)
test? (
${RDEPEND}
dev-python/mock[${PYTHON_USEDEP}]
dev-python/psutil[${PYTHON_USEDEP}]
dev-python/pyopenssl[${PYTHON_USEDEP}]
dev-python/pysendfile[${PYTHON_USEDEP}]
dev-python/pytest[${PYTHON_USEDEP}]
)
"
python_prepare_all() {
sed -i "s/'sphinx.ext.intersphinx'//" docs/conf.py || die
distutils-r1_python_prepare_all
}
python_compile_all() {
if use doc; then
sphinx-build docs docs/_build/html || die
HTML_DOCS=( docs/_build/html/. )
fi
}
python_test() {
# Skip tests which sometimes fail:
# https://github.com/giampaolo/pyftpdlib/issues/470
# https://github.com/giampaolo/pyftpdlib/issues/471
py.test --ignore ${PN}/test/test_misc.py -k \
"not (test_idle_data_timeout2 or test_on_incomplete_file_received)" \
|| die "Tests failed with ${EPYTHON}"
# These tests fail when passing additional options to py.test
# so we need to run them separately
py.test ${PN}/test/test_misc.py || die "Tests failed with ${EPYTHON}"
}
python_install_all() {
if use examples; then
docinto examples
dodoc -r demo/.
docompress -x /usr/share/doc/${PF}/examples
fi
distutils-r1_python_install_all
}
pkg_postinst() {
if [[ -z ${REPLACING_VERSIONS} ]] && \
[[ ${PYTHON_TARGETS} == *python2_7* ]] && \
! has_version dev-python/pysendfile ; then
elog "dev-python/pysendfile is not installed"
elog "It can considerably speed up file transfers for Python 2"
fi
}
|
GitWeb