dev-python/sphinxcontrib-plantuml/sphinxcontrib-plantuml-0.25.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_11 )

inherit distutils-r1

DESCRIPTION="Sphinx extensions for PlantUML"
HOMEPAGE="https://github.com/sphinx-contrib/plantuml/"
SRC_URI="
	https://github.com/sphinx-contrib/plantuml/archive/refs/tags/${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64"

S="${WORKDIR}/${P#sphinxcontrib-}"

BDEPEND="
	test? (
		  app-text/texlive
		  dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
		  dev-tex/latexmk
		  dev-texlive/texlive-fontutils
		  dev-texlive/texlive-latexextra
	)
"

distutils_enable_tests pytest

python_test() {
	# Fix for sphinx.errors.ExtensionError: Could not import extension sphinxcontrib.applehelp
	# See https://projects.gentoo.org/python/guide/test.html#importerrors-for-c-extensions, thanks to mgorny.
	rm -rf sphinxcontrib || die

	epytest
}