blob: 4f45ca8b516be3544f7c731e63e113dd9d649d81 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
USE_RUBY="ruby26 ruby27"
RUBY_FAKEGEM_RECIPE_DOC=""
RUBY_FAKEGEM_DOCDIR=""
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
RUBY_FAKEGEM_GEMSPEC="activestorage.gemspec"
RUBY_FAKEGEM_EXTRAINSTALL="app config db"
RUBY_FAKEGEM_BINWRAP=""
inherit ruby-fakegem
DESCRIPTION="Attach cloud and local files in Rails applications"
HOMEPAGE="https://github.com/rails/rails"
SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
LICENSE="MIT"
SLOT="$(ver_cut 1-2)"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""
RUBY_S="rails-${PV}/${PN}"
DEPEND+=" test? ( app-text/mupdf media-gfx/imagemagick[jpeg,png,tiff] media-video/ffmpeg app-text/poppler[utils] ) "
ruby_add_rdepend "
~dev-ruby/actionpack-${PV}:*
~dev-ruby/activerecord-${PV}:*
dev-ruby/marcel:1.0
"
ruby_add_bdepend "
test? (
~dev-ruby/railties-${PV}
>=dev-ruby/image_processing-1.2:0
dev-ruby/test-unit:2
dev-ruby/mini_magick
dev-ruby/mocha
dev-ruby/rake
dev-ruby/sqlite3
)"
all_ruby_prepare() {
# Remove items from the common Gemfile that we don't need for this
# test run. This also requires handling some gemspecs.
sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|'mysql'\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|sprockets-rails\|redcarpet\|bcrypt\|uglifier\|aws-sdk-s3\|aws-sdk-sns\|google-cloud-storage\|azure-storage\|blade\|bootsnap\|hiredis\|qunit-selenium\|chromedriver-helper\|redis\|rb-inotify\|sprockets\|stackprof\|websocket-client-simple\|libxml-ruby\|sass-rails\|rubocop\|capybara\|rack-cache\|selenium\|dalli\|listen\|connection_pool\|puma\|mysql2\|webdrivers\|webpacker\|rexml\|webmock\)/ s:^:#:" \
-e '/dalli/ s/2.7.7/2.7.9/' \
-e '/:job/,/end/ s:^:#:' \
-e '/:test/,/^end/ s:^:#:' \
-e '/group :doc/,/^end/ s:^:#:' ../Gemfile || die
rm ../Gemfile.lock || die
# Skip test that has already been updated in later versions upstream
sed -i -e '/resized variation of BMP blob/askip "broken test"' test/models/variant_test.rb || die
}
|
GitWeb
