summaryrefslogtreecommitdiff
blob: f669900497afc7b3ffb8364ca70c8e84502aed4e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit multilib

DESCRIPTION="A set of extensions to TCL"
HOMEPAGE="http://tclx.sourceforge.net"
SRC_URI="https://github.com/flightaware/${PN}/archive/v${PV}.tar.gz"

LICENSE="BSD"
IUSE="threads"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~x86-macos"

DEPEND="dev-lang/tcl:0="
RDEPEND="${DEPEND}"

# tests broken, bug #279283
RESTRICT="test"

PATCHES=(
		"${FILESDIR}"/${PN}-8.4-varinit.patch
		"${FILESDIR}"/${PN}-8.4-ldflags.patch
)

src_prepare() {
	sed \
		-e '/CC=/s:-pipe::g' \
		-i tclconfig/tcl.m4 configure || die
	default
}

src_configure() {
	econf \
		$(use_enable threads) \
		--enable-shared \
		--with-tcl="${EPREFIX}/usr/$(get_libdir)/"

	# adjust install_name on darwin
	if [[ ${CHOST} == *-darwin* ]]; then
		sed -i \
			-e 's:^\(SHLIB_LD\W.*\)$:\1 -install_name ${pkglibdir}/$@:' \
				"${S}"/Makefile || die 'sed failed'
	fi
}

src_install() {
	default
	doman doc/*.[n3]
}