summaryrefslogtreecommitdiff
blob: e8b393a9a6d11eb5a1dca195660f1cf9c061f15f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

WX_GTK_VER="3.0"
inherit cmake xdg-utils wxwidgets

DESCRIPTION="The official lobby client for SpringRTS community games"
HOMEPAGE="https://springlobby.springrts.com"
SRC_URI="https://springlobby.springrts.com/dl/stable/${P}.tar.bz2"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug +libnotify +nls +sound"

RDEPEND="
	dev-libs/openssl:0=
	net-misc/curl
	sys-libs/zlib[minizip]
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libXext
	x11-libs/wxGTK:${WX_GTK_VER}[X]
	libnotify? ( x11-libs/libnotify )
	sound? (
		media-libs/alure
		media-libs/openal
	)
"

BDEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
"

src_configure() {
	setup-wxwidgets
	local mycmakeargs=(
		-DOPTION_NOTIFY=$(usex libnotify)
		-DOPTION_SOUND=$(usex sound)
		-DOPTION_TRANSLATION_SUPPORT=$(usex nls)
		-DAUX_VERSION="(Gentoo,${ARCH})"
		)
	cmake_src_configure
}

pkg_postinst() {
	xdg_icon_cache_update
}

pkg_postrm() {
	xdg_icon_cache_update
}