blob: 9667da5811bf6e470336eb5ba4a1e5ba384b0495 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
GNOME2_LA_PUNT="yes"
GNOME2_EAUTORECONF="yes"
inherit gnome2 systemd
DESCRIPTION="Virtual filesystem implementation for gio"
HOMEPAGE="https://wiki.gnome.org/Projects/gvfs"
SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
LICENSE="LGPL-2+"
SLOT="0"
IUSE="afp archive bluray cdda elogind fuse google gnome-keyring gnome-online-accounts gphoto2 gtk +http ios mtp nfs policykit samba systemd test +udev udisks zeroconf"
REQUIRED_USE="
cdda? ( udev )
elogind? ( !systemd udisks )
google? ( gnome-online-accounts )
mtp? ( udev )
udisks? ( udev )
systemd? ( !elogind udisks )
"
KEYWORDS="alpha amd64 arm ~arm64 ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
RDEPEND="
app-crypt/gcr:=
>=dev-libs/glib-2.51:2
dev-libs/libxml2:2
net-misc/openssh
afp? ( >=dev-libs/libgcrypt-1.2.2:0= )
archive? ( app-arch/libarchive:= )
bluray? ( media-libs/libbluray:= )
elogind? ( >=sys-auth/elogind-229:0= )
fuse? ( >=sys-fs/fuse-2.8.0:0 )
gnome-keyring? ( app-crypt/libsecret )
gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.7.1:= )
google? (
>=dev-libs/libgdata-0.17.7:=[crypt,gnome-online-accounts]
>=net-libs/gnome-online-accounts-3.17.1:= )
gphoto2? ( >=media-libs/libgphoto2-2.5.0:= )
gtk? ( >=x11-libs/gtk+-3.0:3 )
http? ( >=net-libs/libsoup-2.42:2.4 )
ios? (
>=app-pda/libimobiledevice-1.2:=
>=app-pda/libplist-1:= )
mtp? (
>=dev-libs/libusb-1.0.21
>=media-libs/libmtp-1.1.12 )
nfs? ( >=net-fs/libnfs-1.9.8 )
policykit? (
sys-auth/polkit
sys-libs/libcap )
samba? ( >=net-fs/samba-4[client] )
systemd? ( >=sys-apps/systemd-206:0= )
udev? (
cdda? ( dev-libs/libcdio-paranoia )
>=virtual/libgudev-147:=
virtual/libudev:= )
udisks? ( >=sys-fs/udisks-1.97:2 )
zeroconf? ( >=net-dns/avahi-0.6[dbus] )
"
DEPEND="${RDEPEND}
app-text/docbook-xsl-stylesheets
dev-libs/libxslt
>=sys-devel/gettext-0.19.4
virtual/pkgconfig
dev-util/gdbus-codegen
dev-util/glib-utils
dev-util/gtk-doc-am
test? (
>=dev-python/twisted-16
|| (
net-analyzer/netcat
net-analyzer/netcat6 ) )
!udev? ( >=dev-libs/libgcrypt-1.2.2:0 )
"
# libgcrypt.m4, provided by libgcrypt, needed for eautoreconf, bug #399043
# test dependencies needed per https://bugzilla.gnome.org/700162
# Tests with multiple failures, this is being handled upstream at:
# https://bugzilla.gnome.org/700162
RESTRICT="test"
PATCHES=(
"${WORKDIR}"/patches/ #599482, 641522, gnome-3-24 backports
"${FILESDIR}"/${PN}-1.30.2-sysmacros.patch #580234
)
src_prepare() {
if ! use udev; then
sed -e 's/gvfsd-burn/ /' \
-e 's/burn.mount.in/ /' \
-e 's/burn.mount/ /' \
-i daemon/Makefile.am || die
fi
gnome2_src_prepare
}
src_configure() {
# --enable-documentation installs man pages
# --disable-obexftp, upstream bug #729945
gnome2_src_configure \
--disable-gdu \
--enable-documentation \
--enable-gcr \
--with-dbus-service-dir="${EPREFIX}"/usr/share/dbus-1/services \
--with-systemduserunitdir="$(systemd_get_userunitdir)" \
$(use_enable afp) \
$(use_enable archive) \
$(use_enable bluray) \
$(use_enable cdda) \
$(use_enable elogind libelogind) \
$(use_enable fuse) \
$(use_enable gnome-keyring keyring) \
$(use_enable gnome-online-accounts goa) \
$(use_enable google) \
$(use_enable gphoto2) \
$(use_enable gtk) \
$(use_enable http) \
$(use_enable ios afc) \
$(use_enable mtp libmtp) \
$(use_enable mtp libusb) \
$(use_enable nfs) \
$(use_enable policykit admin) \
$(use_enable samba) \
$(use_enable systemd libsystemd-login) \
$(use_enable udev gudev) \
$(use_enable udev) \
$(use_enable udisks udisks2) \
$(use_enable zeroconf avahi)
}
|
GitWeb