summaryrefslogtreecommitdiff
blob: 334fd0b86976d2e313666cec78af66e3c41d6801 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

CMAKE_MIN_VERSION="3.0"
KDE_TEST="true"
inherit kde5

DESCRIPTION="Plugins for the KDE Image Plugin Interface"
HOMEPAGE="https://www.digikam.org/"

LICENSE="GPL-2+"
KEYWORDS="amd64 x86"
IUSE="flashexport mediawiki +remotestorage vkontakte"

if [[ ${KDE_BUILD_TYPE} = release ]]; then
	MY_PV="${PV/_/-}"
	MY_P="digikam-${MY_PV}"

	if [[ ${PV} =~ beta[0-9]$ ]]; then
		SRC_BRANCH="unstable"
	else
		SRC_BRANCH="stable"
	fi

	SRC_URI="mirror://kde/${SRC_BRANCH}/digikam/${MY_P}.tar.xz"

	S="${WORKDIR}/${MY_P}/extra/${PN}"
fi

COMMON_DEPEND="
	$(add_frameworks_dep kcompletion)
	$(add_frameworks_dep kconfig)
	$(add_frameworks_dep kconfigwidgets)
	$(add_frameworks_dep kcoreaddons)
	$(add_frameworks_dep ki18n)
	$(add_frameworks_dep kwindowsystem)
	$(add_frameworks_dep kxmlgui)
	$(add_kdeapps_dep libkipi '' '16.08.3-r1' '5=')
	$(add_qt_dep qtgui)
	$(add_qt_dep qtnetwork)
	$(add_qt_dep qtprintsupport)
	$(add_qt_dep qtsvg)
	$(add_qt_dep qtwidgets)
	$(add_qt_dep qtxml)
	$(add_qt_dep qtxmlpatterns)
	flashexport? ( $(add_frameworks_dep karchive) )
	mediawiki? ( net-libs/libmediawiki:5 )
	remotestorage? ( $(add_frameworks_dep kio) )
	vkontakte? ( net-libs/libkvkontakte:5 )
"
DEPEND="${COMMON_DEPEND}
	$(add_qt_dep qtconcurrent)
	sys-devel/gettext
"
RDEPEND="${COMMON_DEPEND}
	!media-plugins/kipi-plugins:4
"

src_prepare() {
	if [[ ${KDE_BUILD_TYPE} = release ]]; then
		if [[ ${SRC_BRANCH} = stable ]]; then
			# prepare the translations
			mv "${WORKDIR}/${MY_P}/po" po || die
			find po -name "*.po" -and -not -name "kipiplugin*.po" -delete || die
			echo "find_package(Gettext REQUIRED)" >> CMakeLists.txt || die
			echo "add_subdirectory( po )" >> CMakeLists.txt || die
		fi
	fi

	kde5_src_prepare
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_find_package flashexport KF5Archive)
		$(cmake-utils_use_find_package mediawiki KF5MediaWiki)
		-DENABLE_KIO=$(usex remotestorage)
		$(cmake-utils_use_find_package vkontakte KF5Vkontakte)
	)

	kde5_src_configure
}