media-plugins/vdr-dvbhddevice/vdr-dvbhddevice-2.2.0_p20180420-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 2020-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit vdr-plugin-2

# 2018/04/20
REVISION="6a3e75484d90"

DESCRIPTION="VDR Plugin: output device for the 'Full Featured' TechnoTrend S2-6400 DVB Card"
HOMEPAGE="https://bitbucket.org/powARman/dvbhddevice"
SRC_URI="https://bitbucket.org/powARman/dvbhddevice/get/${REVISION}.tar.bz2 ->
		${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"

DEPEND=">=media-video/vdr-2.0.0"
RDEPEND="${DEPEND}"

PATCHES=(
	"${FILESDIR}/convert-bool-fix.patch"
	"${FILESDIR}/define_AUDIO_GET_PTS.patch" )
QA_FLAGS_IGNORED="
	usr/lib/vdr/plugins/libvdr-dvbhddevice.*
	usr/lib64/vdr/plugins/libvdr-dvbhddevice.*"

S="${WORKDIR}/powARman-${VDRPLUGIN}-${REVISION}"

src_prepare() {
	vdr-plugin-2_src_prepare

	fix_vdr_libsi_include dvbhdffdevice.c
}

src_install() {
	vdr-plugin-2_src_install

	doheader dvbhdffdevice.h hdffcmd.h
	insinto /usr/include/libhdffcmd
	doins libhdffcmd/*.h
}