summaryrefslogtreecommitdiff
blob: f40fc7b8e73d890816edc91c172d9acbce73b931 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
# Copyright 2019-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
inherit cmake readme.gentoo-r1

DESCRIPTION="PulseAudio modules for LDAC, aptX, aptX HD, and AAC for Bluetooth"
HOMEPAGE="https://github.com/EHfive/pulseaudio-modules-bt"

PULSE_VER="15.0"
SRC_URI="
	https://github.com/EHfive/pulseaudio-modules-bt/archive/v${PV}.tar.gz -> ${P}.tar.gz
	https://freedesktop.org/software/pulseaudio/releases/pulseaudio-${PULSE_VER}.tar.xz
"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="fdk +ffmpeg +ldac +native-headset ofono-headset"

DEPEND="
	fdk? ( media-libs/fdk-aac:0= )
	ffmpeg? ( media-video/ffmpeg )
	media-libs/sbc
	ldac? ( media-libs/libldac )
	>=net-wireless/bluez-5
	>=sys-apps/dbus-1.0.0
	ofono-headset? ( >=net-misc/ofono-1.13 )
	|| (
		>=media-sound/pulseaudio-daemon-${PULSE_VER}[-bluetooth]
		>=media-sound/pulseaudio-${PULSE_VER}[-bluetooth,daemon(+)]
	)
	!media-sound/pulseaudio[bluetooth]
"
# Ordinarily media-libs/libldac should be in DEPEND too, but for now upstream repo is using a ldac submodule instead.
RDEPEND="${DEPEND}"
BDEPEND=""

DISABLE_AUTOFORMATTING="no"
DOC_CONTENTS="
After getting media-sound/pulseaudio merged without its bluetooth
support (to not collide with this) you may have removed the loading
of bluetooth modules in default.pa config file, leading to failure
to use your bluetooth device (see
https://github.com/EHfive/pulseaudio-modules-bt/issues/33).
Please ensure you have this lines present in your /etc/pulse/default.pa
file:

.ifexists module-bluetooth-policy.so
load-module module-bluetooth-policy
.endif

.ifexists module-bluetooth-discover.so
load-module module-bluetooth-discover
.endif
"

src_prepare() {
	cmake_src_prepare

	# pulseaudio headers needed to build
	rmdir pa/ || die
	ln -s ../pulseaudio-${PULSE_VER}/ pa || die
}

src_configure() {
	local mycmakeargs=(
		-DCODEC_AAC_FDK=$(usex fdk "ON" "OFF")
		-DCODEC_APTX_FF=$(usex ffmpeg "ON" "OFF")
		-DCODEC_APTX_HD_FF=$(usex ffmpeg "ON" "OFF")
		-DCODEC_LDAC=$(usex ldac "ON" "OFF")
		-DNATIVE_HEADSET=$(usex native-headset "ON" "OFF")
		-DOFONO_HEADSET=$(usex ofono-headset "ON" "OFF")
	)
	cmake_src_configure
}

src_install() {
	cmake_src_install
	readme.gentoo_create_doc
}

pkg_postinst() {
	readme.gentoo_print_elog
}