summaryrefslogtreecommitdiff
blob: ebdc2e33415eef2494afe565953e0eb30b25faa4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

# TODO: convert
#	dev-python/gconf-python
#	dev-python/gnome-vfs-python
#	dev-python/libgnome-python
# See bug #477814

EAPI=5

GCONF_DEBUG=no
PYTHON_COMPAT=( python2_7 )
inherit gnome2 multilib python-single-r1

DESCRIPTION="A simple audiofile converter application for the GNOME environment"
HOMEPAGE="http://soundconverter.org/"
SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="aac flac mp3 opus vorbis"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="${PYTHON_DEPS}
	dev-python/gconf-python
	dev-python/gnome-vfs-python
	=dev-python/gst-python-0.10*[${PYTHON_USEDEP}]
	dev-python/pygobject:2[${PYTHON_USEDEP}]
	>=dev-python/pygtk-2.12[${PYTHON_USEDEP}]
	dev-python/libgnome-python
	gnome-base/libglade
	aac? (
		=media-plugins/gst-plugins-faac-0.10*
		=media-plugins/gst-plugins-faad-0.10*
		)
	flac? ( =media-plugins/gst-plugins-flac-0.10* )
	mp3? (
		=media-plugins/gst-plugins-lame-0.10*
		=media-plugins/gst-plugins-mad-0.10*
		=media-plugins/gst-plugins-taglib-0.10*
		)
	vorbis? (
		=media-plugins/gst-plugins-ogg-0.10*
		=media-plugins/gst-plugins-vorbis-0.10*
		)
	opus? (
		=media-plugins/gst-plugins-opus-0.10*
		)
"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	dev-util/intltool
	virtual/pkgconfig
	sys-devel/gettext
"

src_prepare() {
	python_fix_shebang .
	gnome2_src_prepare
}

src_install() {
	gnome2_src_install
	python_optimize "${ED%/}"/usr/$(get_libdir)/soundconverter/python
}