summaryrefslogtreecommitdiff
blob: 47a44a77c21ca5536cfaa58fa75c915415073aa5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI="6"
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="sqlite"
DISTUTILS_SINGLE_IMPL=1

inherit distutils-r1

DESCRIPTION="Movie slideshow creator using Ken Burns effect"
HOMEPAGE="http://www.photofilmstrip.org"
SRC_URI="mirror://sourceforge/photostoryx/${PN}/${PV}/${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"

KEYWORDS="~amd64 ~x86"
IUSE="cairo sdl"

RDEPEND="dev-python/wxpython:2.8[cairo?,${PYTHON_USEDEP}]
	dev-python/pillow[${PYTHON_USEDEP}]
	media-video/mplayer[encode]
	sdl? ( dev-python/pygame[${PYTHON_USEDEP}] )"

DEPEND="${RDEPEND}"

# Fix bug #472774 (https://bugs.gentoo.org/show_bug.cgi?id=472774)
PATCHES=(
	"${FILESDIR}/${P}-PIL_modules_imports_fix.patch"
)

DOCS=( CHANGES COPYING README )

src_prepare() {
	# Remove unneeded icon resources update needing running X
	# Fix app doc/help files paths
	sed -i \
		-e '/self\._make_resources\(\)/d' \
		-e "s:\(os\.path\.join(\"share\", \"doc\", \"\)photofilmstrip:\1${PF}:" \
		setup.py || die

	sed -i \
		 -e "s:\"photofilmstrip\":\"${PF}\":" \
		 photofilmstrip/gui/HelpViewer.py || die

	# Fix desktop file entry
	sed -i \
		-e '/^Version.*/d' \
		data/photofilmstrip.desktop || die

	distutils-r1_src_prepare
}

src_install() {
	doman docs/manpage/*

	# Do not compress the apps help files
	docompress -x /usr/share/doc/${PF}/${PN}.hh{c,k,p}

	distutils-r1_src_install
}