summaryrefslogtreecommitdiff
blob: f013ad81132197d0e8c859de88fc503447013808 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

inherit cmake-utils

DESCRIPTION="Data receiver of the SMB Traffic Analyzer project"
HOMEPAGE="https://github.com/hhetter/smbtad"
SRC_URI="http://morelias.org/smbta/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

DEPEND="
	dev-db/libdbi
	dev-libs/iniparser:0
	sys-libs/talloc
"
RDEPEND="${DEPEND}
	|| (
		<net-fs/samba-3.6[smbtav2]
		>=net-fs/samba-3.6
	)
"

DOCS=( README AUTHORS )

src_prepare() {
	cmake-utils_src_prepare

	sed -i \
		-e '/CMAKE_C_FLAGS/d' \
		CMakeLists.txt || die
}

src_configure() {
	local mycmakeargs=(
		-DDebug=$(usex debug)
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	newinitd "${FILESDIR}"/smbtad.rc smbtad
	newconfd dist/smbtad.conf_example smbtad.conf
}