blob: 7750baa97aefacc308e2086131439b7496cbaf19 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_OPTIONAL=1
NEED_EMACS="24.1"
PYTHON_COMPAT=( python3_{6,7} )
inherit bash-completion-r1 distutils-r1 elisp-common eutils flag-o-matic \
pax-utils readme.gentoo-r1 toolchain-funcs
DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
HOMEPAGE="https://notmuchmail.org/"
SRC_URI="https://notmuchmail.org/releases/${P}.tar.xz
test? ( https://notmuchmail.org/releases/test-databases/database-v1.tar.xz )"
LICENSE="GPL-3"
# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y. Bump of Y is
# meant to be binary backward compatible.
SLOT="0/5"
KEYWORDS="~alpha ~amd64 ~ppc64 ~x86 ~x64-solaris"
REQUIRED_USE="
nmbug? ( python )
python? ( ${PYTHON_REQUIRED_USE} )
test? ( crypt emacs python valgrind )
"
IUSE="crypt doc emacs mutt nmbug python test valgrind"
RESTRICT="!test? ( test )"
BDEPEND="
virtual/pkgconfig
doc? (
app-doc/doxygen
dev-python/mock[${PYTHON_USEDEP}]
dev-python/sphinx
sys-apps/texinfo
)
"
CDEPEND="
dev-libs/glib
dev-libs/gmime:3.0[crypt]
>=dev-libs/xapian-1.4.8:=
sys-libs/talloc
sys-libs/zlib
emacs? ( >=app-editors/emacs-${NEED_EMACS}:* )
python? ( ${PYTHON_DEPS} )
"
DEPEND="${CDEPEND}
test? (
>=app-editors/emacs-${NEED_EMACS}:*[libxml2]
app-misc/dtach
sys-devel/gdb
crypt? ( app-crypt/gnupg dev-libs/openssl )
)
valgrind? ( dev-util/valgrind )
"
RDEPEND="${CDEPEND}
crypt? ( app-crypt/gnupg )
mutt? (
dev-perl/File-Which
dev-perl/Mail-Box
dev-perl/MailTools
dev-perl/String-ShellQuote
dev-perl/Term-ReadLine-Gnu
virtual/perl-Digest-SHA
virtual/perl-File-Path
virtual/perl-Getopt-Long
virtual/perl-Pod-Parser
)
nmbug? ( dev-vcs/git )
"
DOCS=( AUTHORS NEWS README )
DOC_CONTENTS="There are a few backward-incompatible changes between
notmuch version 0.18 < x <= 0.18. Please consult the NEWS file (0.18
section) before first use."
MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"
PATCHES=(
"${FILESDIR}/${PV}-0001-Use-loopback-IP-address-rather-than-name.patch"
)
SITEFILE="50${PN}-gentoo.el"
bindings() {
local rc=0
if use $1; then
pushd bindings/$1 || die
shift
"$@"
rc=$?
popd || die
fi
return $rc
}
pkg_setup() {
use emacs && elisp-check-emacs-version
}
src_unpack() {
unpack "${P}".tar.xz
if use test; then
mkdir -p "${S}"/test/test-databases || die
cp "${DISTDIR}"/database-v1.tar.xz "${S}"/test/test-databases/ || die
fi
}
src_prepare() {
local _deps=""
default
# Python bindings
bindings python distutils-r1_src_prepare
bindings python mv README README-python || die
mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
# Ensure that a new Makefile.config will be generated
rm -f Makefile.config || die
# Override dependencies for 'install' target
use doc && _deps="install-info"
sed -e "s/^install:.\+/install: all ${_deps}/" -i Makefile.local || die
if use test; then
append-cflags -g
append-cxxflags -g
fi
if [[ ${CHOST} == *-solaris* ]] ; then
# Non-autoconf configure
append-ldflags -lnsl -lsocket
fi
}
src_configure() {
python_setup # For sphinx
local _args=(
--bashcompletiondir="$(get_bashcompdir)"
--emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
--emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
--without-desktop
--without-ruby
--zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
$(use_with emacs)
$(use_with doc api-docs)
)
tc-export CC CXX
econf "${_args[@]}"
}
src_compile() {
python_setup # For sphinx
V=1 default
bindings python distutils-r1_src_compile
if use mutt; then
pushd contrib/notmuch-mutt || die
emake notmuch-mutt.1
popd || die
fi
if use doc; then
pydocs() {
pushd docs || die
emake html
rm -r html/_sources || die
rm html/{objects.inv,.buildinfo} || die
mkdir -p ../html && mv html ../html/python || die
popd || die
}
LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
fi
}
src_test() {
pax-mark -m notmuch
LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" V=1 default
pax-mark -ze notmuch
}
src_install() {
default
if use doc; then
doman doc/_build/man/man?/*.?
fi
if use emacs; then
elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
fi
if use nmbug; then
dobin devel/nmbug/nmbug
dobin devel/nmbug/notmuch-report
fi
if use mutt; then
pushd contrib/notmuch-mutt || die
dobin notmuch-mutt
doman notmuch-mutt.1
insinto /etc/mutt
doins notmuch-mutt.rc
dodoc README-mutt
popd || die
fi
DOCS="" bindings python distutils-r1_src_install
use doc && bindings python dodoc -r html
}
pkg_preinst() {
local _rcfile="/etc/mutt/notmuch-mutt.rc"
if use mutt && ! [[ -e ${ROOT}${_rcfile} ]]; then
elog "To enable notmuch support in mutt, add the following line"
elog "to your mutt config file:"
elog ""
elog " source ${_rcfile}"
fi
}
pkg_postinst() {
use emacs && elisp-site-regen
if has_version '<net-mail/notmuch-0.18'; then
FORCE_PRINT_ELOG=1 readme.gentoo_print_elog
fi
}
pkg_postrm() {
use emacs && elisp-site-regen
}
|
GitWeb