summaryrefslogtreecommitdiff
blob: 573500aacb93be796aaddc1c2e13177d59560021 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs systemd

DESCRIPTION="IP multicast routing daemon"
HOMEPAGE="https://troglobit.com/projects/mrouted/"
SRC_URI="https://github.com/troglobit/${PN}/releases/download/${PV}/${P}.tar.gz"

LICENSE="Stanford GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="rsrr test"

# Needs unshare
RESTRICT="!test? ( test ) test"

BDEPEND="virtual/pkgconfig
	app-alternatives/yacc"

src_configure() {
	tc-export CC CXX

	econf \
		$(usev rsrr --enable-rsrr) \
		$(use_enable test)
}

src_compile() {
	emake CC="$(tc-getCC)" CXX="$(tc-getCXX)"
}

src_install() {
	default

	insinto /etc
	doins mrouted.conf

	newinitd "${FILESDIR}"/mrouted.rc mrouted
	systemd_dounit mrouted.service
}