summaryrefslogtreecommitdiff
blob: 7239efcfe45c48146fc375522316abcd5625bc85 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs

DESCRIPTION="STAR aligner: align RNA-seq reads to reference genome uncompressed suffix arrays"
HOMEPAGE="https://github.com/alexdobin/STAR"
SRC_URI="https://github.com/alexdobin/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"

RDEPEND="sci-libs/htslib:="
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"

PATCHES=( "${FILESDIR}"/${PN}-2.7.10a-fix-build-system.patch )
DOCS=( README.md CHANGES.md RELEASEnotes.md doc/STARmanual.pdf )

pkg_pretend() {
	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
}

pkg_setup() {
	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
}

src_prepare() {
	default

	# remove bundled htslib
	rm -r source/htslib || die
}

src_configure() {
	tc-export CC CXX PKG_CONFIG
}

src_compile() {
	emake -C source STAR
}

src_install() {
	dobin source/STAR
	einstalldocs
}