summaryrefslogtreecommitdiff
blob: 27daf4976fd84bf39ff3db5241cc9568a3a82107 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit cmake flag-o-matic

DESCRIPTION="A 3D multiple robot simulator with dynamics"
HOMEPAGE="http://gazebosim.org/"
SRC_URI="https://osrf-distributions.s3.amazonaws.com/gazebo/releases/${P}.tar.bz2"

LICENSE="Apache-2.0"
# Subslot = major version = soname of libs
SLOT="0/11"
KEYWORDS="~amd64"
IUSE="cpu_flags_x86_sse2 test"
RESTRICT="!test? ( test )"

RDEPEND="
	>=dev-libs/protobuf-2:=
	virtual/opengl
	media-libs/openal
	net-misc/curl
	dev-libs/tinyxml
	>=dev-libs/tinyxml2-6:=
	dev-libs/libtar
	dev-cpp/tbb:=
	>=dev-games/ogre-1.7.4:=[freeimage]
	<dev-games/ogre-1.10
	>=media-libs/freeimage-3.15.4[png]
	sci-libs/libccd
	>=media-video/ffmpeg-2.6:0=
	sci-libs/gts
	>=sci-physics/bullet-2.82:=
	>=dev-libs/sdformat-9.8:=
	dev-qt/qtwidgets:5
	dev-qt/qtcore:5
	dev-qt/qtopengl:5
	dev-libs/boost:=[threads(+)]
	sci-libs/gdal:=
	virtual/libusb:1
	dev-libs/libspnav
	media-libs/freeimage
	sci-libs/hdf5:=[cxx]
	sys-apps/util-linux
	>=media-gfx/graphviz-4
	net-libs/ignition-msgs:5=
	sci-libs/ignition-math:6=
	net-libs/ignition-transport:8=
	sci-libs/ignition-common:3=
	sci-libs/ignition-fuel-tools:4=
	x11-libs/qwt:6=[qt5(+)]
"
DEPEND="${RDEPEND}
	dev-qt/qttest:5
	x11-apps/mesa-progs
	test? ( dev-libs/libxslt )
"
BDEPEND="
	|| ( app-text/ronn-ng app-text/ronn )
	app-arch/gzip
	virtual/pkgconfig
"
CMAKE_BUILD_TYPE=RelWithDebInfo
PATCHES=(
	"${FILESDIR}/qwt2.patch"
	"${FILESDIR}/cmake.patch"
	"${FILESDIR}/gv.patch"
)

src_configure() {
	# find OGRE properly
	sed -e "s#lib/OGRE#$(get_libdir)/OGRE#" -i cmake/gazebo-config.cmake.in || die

	local mycmakeargs=(
		"-DUSE_UPSTREAM_CFLAGS=OFF"
		"-DSSE2_FOUND=$(usex cpu_flags_x86_sse2 TRUE FALSE)"
		"-DUSE_HOST_CFLAGS=FALSE"
		"-DBUILD_TESTING=$(usex test TRUE FALSE)"
		"-DENABLE_SCREEN_TESTS=FALSE"
		"-DUSE_EXTERNAL_TINYXML2=TRUE"
	)
	cmake_src_configure
}