blob: 1776c7b0afb3c4bcd3d31748482519f381c6e324 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
PLOCALES="ar cs de en es et fr hr hu id_ID it ja nl pl pt_BR pt ru sk sv uk vi zh_CN zh_TW"
inherit fdo-mime gnome2-utils git-r3 l10n qmake-utils
DESCRIPTION="A Qt based map editor for the openstreetmap.org project"
HOMEPAGE="http://www.merkaartor.be https://github.com/openstreetmap/merkaartor"
SRC_URI=""
EGIT_REPO_URI="https://github.com/openstreetmap/merkaartor.git"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="debug exif gps libproxy qrcode qt5"
REQUIRED_USE="qrcode? ( !qt5 )"
RDEPEND="
!qt5? (
dev-qt/qtcore:4
dev-qt/qtgui:4
dev-qt/qtsingleapplication[qt4]
dev-qt/qtsvg:4
dev-qt/qtwebkit:4
)
qt5? (
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtprintsupport:5
dev-qt/qtsvg:5
dev-qt/qtwebkit:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
)
dev-qt/qtsingleapplication[X,qt5?]
>=sci-libs/gdal-1.6.0
>=sci-libs/proj-4.6
sys-libs/zlib
exif? ( media-gfx/exiv2:= )
gps? ( >=sci-geosciences/gpsd-3.13[cxx] )
libproxy? ( net-libs/libproxy )
qrcode? ( media-gfx/zbar[qt4] )
"
DEPEND="${RDEPEND}
qt5? ( dev-qt/linguist-tools:5 )
virtual/pkgconfig
"
DOCS=( AUTHORS CHANGELOG )
src_unpack() {
git-r3_src_unpack
}
src_prepare() {
default
my_rm_loc() {
sed -i -e "s:../translations/${PN}_${1}.\(ts\|qm\)::" src/src.pro || die
rm "translations/${PN}_${1}.ts" || die
}
if [[ -n "$(l10n_get_locales)" ]]; then
l10n_for_each_disabled_locale_do my_rm_loc
if use qt5 ; then
$(qt5_get_bindir)/lrelease src/src.pro || die
else
$(qt4_get_bindir)/lrelease src/src.pro || die
fi
fi
# build system expects to be building from git
if [[ ${PV} != *9999 ]] ; then
sed -i "${S}"/src/Config.pri -e "s:SION = .*:SION = \"${PV}\":g" || die
fi
}
src_configure() {
# TRANSDIR_SYSTEM is for bug #385671
if use qt5 ; then
eqmake5 \
PREFIX="${ED}usr" \
LIBDIR="${ED}usr/$(get_libdir)" \
TRANSDIR_MERKAARTOR="${ED}usr/share/${PN}/translations" \
TRANSDIR_SYSTEM="${EPREFIX}/usr/share/qt5/translations" \
SYSTEM_QTSA=1 \
NODEBUG="$(usex debug '0' '1')" \
GEOIMAGE="$(usex exif '1' '0')" \
GPSDLIB="$(usex gps '1' '0')" \
LIBPROXY="$(usex libproxy '1' '0')" \
ZBAR="$(usex qrcode '1' '0')" \
Merkaartor.pro
else
eqmake4 \
PREFIX="${ED}usr" \
LIBDIR="${ED}usr/$(get_libdir)" \
TRANSDIR_MERKAARTOR="${ED}usr/share/${PN}/translations" \
TRANSDIR_SYSTEM="${EPREFIX}/usr/share/qt4/translations" \
SYSTEM_QTSA=1 \
NODEBUG="$(usex debug '0' '1')" \
GEOIMAGE="$(usex exif '1' '0')" \
GPSDLIB="$(usex gps '1' '0')" \
LIBPROXY="$(usex libproxy '1' '0')" \
ZBAR="$(usex qrcode '1' '0')" \
Merkaartor.pro
fi
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
fdo-mime_desktop_database_update
gnome2_icon_cache_update
}
pkg_postrm() {
fdo-mime_desktop_database_update
gnome2_icon_cache_update
}
|
GitWeb