summaryrefslogtreecommitdiff
blob: 327ffeed1ef85a41f612f7931603ad5a0e56f250 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DESCRIPTION="C library for high-throughput sequencing data formats"
HOMEPAGE="http://www.htslib.org/"
SRC_URI="mirror://sourceforge/samtools/${PV}/${P}.tar.bz2"

SLOT="0/2"
LICENSE="MIT"
KEYWORDS="amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="+bzip2 curl +lzma static-libs"

RDEPEND="
	bzip2? ( app-arch/bzip2:= )
	curl? ( net-misc/curl )
	lzma? ( app-arch/xz-utils:= )"
DEPEND="${RDEPEND}"

src_prepare() {
	default

	# upstream injects LDFLAGS into the .pc file,
	# which is a big nono for QA
	sed 's/private_LIBS=$LDFLAGS/private_LIBS=""/g' -i configure || die
}

src_configure() {
	econf \
		--disable-gcs \
		--disable-plugins \
		--disable-s3 \
		$(use_enable bzip2 bz2) \
		$(use_enable curl libcurl) \
		$(use_enable lzma)
}

src_install() {
	default

	if ! use static-libs; then
		find "${D}" -name '*.a' -delete || die
	fi
}