blob: 313b919e089d8648f36fe53c2c31c19dd3ce02f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools toolchain-funcs
DESCRIPTION="UEFI boot manager from systemd (formerly gummiboot)"
HOMEPAGE="https://www.freedesktop.org/wiki/Software/systemd/systemd-boot/"
SRC_URI="https://github.com/systemd/systemd/archive/v${PV}.tar.gz -> systemd-${PV}.tar.gz"
LICENSE="GPL-2 LGPL-2.1 MIT public-domain"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""
RESTRICT="test"
COMMON_DEPEND="
>=sys-apps/util-linux-2.27.1
"
DEPEND="${COMMON_DEPEND}
app-text/docbook-xml-dtd:4.2
app-text/docbook-xml-dtd:4.5
app-text/docbook-xsl-stylesheets
dev-libs/libxslt:0
>=dev-util/intltool-0.50
dev-util/gperf
>=sys-boot/gnu-efi-3.0.2
sys-libs/libcap
virtual/pkgconfig
"
RDEPEND="${COMMON_DEPEND}
!sys-apps/systemd
"
S="${WORKDIR}/systemd-${PV}"
PATCHES=(
"${FILESDIR}"/233-Force-libsystemd-shared-to-be-static.patch
)
src_prepare() {
default
eautoreconf
}
src_configure() {
local myeconfargs=(
EFI_CC="$(tc-getPROG "EFI_CC CC" gcc)"
cc_cv_CFLAGS__flto=no
cc_cv_LDFLAGS__Wl__fuse_ld_gold=no
--enable-blkid
--enable-efi
--enable-gnuefi
--disable-acl
--disable-apparmor
--disable-audit
--disable-bzip2
--disable-elfutils
--disable-gcrypt
--disable-gnutls
--disable-kmod
--disable-libcryptsetup
--disable-libcurl
--disable-libidn
--disable-lz4
--disable-microhttpd
--disable-myhostname
--disable-pam
--disable-qrencode
--disable-seccomp
--disable-selinux
--disable-xkbcommon
--disable-xz
--disable-zlib
)
econf "${myeconfargs[@]}"
}
src_compile() {
local targets=(
bootctl
man/bootctl.1
man/kernel-install.8
'$(bootlib_DATA)'
)
emake built-sources
echo "gentoo: ${targets[*]}" | emake -f Makefile -f - gentoo
}
src_install() {
local args=(
DESTDIR="${D%/}"
# bootctl
bin_PROGRAMS=bootctl
install-binPROGRAMS
# kernel-install
install-dist_binSCRIPTS
install-dist_kernelinstallSCRIPTS
man_MANS="man/bootctl.1 man/kernel-install.8"
install-man1
install-man8
install-bootlibDATA
)
emake "${args[@]}"
einstalldocs
}
|
GitWeb