From da8da8616bc4c92caab983b84003f3aa12ad0445 Mon Sep 17 00:00:00 2001
From: Takuya Wakazono <pastalian46@gmail.com>
Date: Fri, 29 Mar 2024 23:37:55 +0900
Subject: dev-libs/librepo: add 1.17.1

Closes: https://bugs.gentoo.org/924463
Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>
---
 dev-libs/librepo/Manifest              |  1 +
 dev-libs/librepo/librepo-1.17.1.ebuild | 51 ++++++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)
 create mode 100644 dev-libs/librepo/librepo-1.17.1.ebuild

diff --git a/dev-libs/librepo/Manifest b/dev-libs/librepo/Manifest
index 9545653c80..6475a917d7 100644
--- a/dev-libs/librepo/Manifest
+++ b/dev-libs/librepo/Manifest
@@ -1 +1,2 @@
 DIST librepo-1.17.0.tar.gz 840253 BLAKE2B 4c764a350546166077b2a6bd1f761bf0ad68e5deccda4ab263f2ce9d3c7b2eaa1c792014d077f13d729a1995ffc8ac2335f9c9e87779db1f3962b40de2d20b59 SHA512 f14446774349545c1122c7d6b9e33a51f38b15a2071543d5e8562975cc7ef1d04b6ddebcf4acdb88ada843e4f9854e0ef792a4b65a4ace4d3d125532c5b92427
+DIST librepo-1.17.1.tar.gz 840461 BLAKE2B 88dbe5fb77ed6aa6ca10342832642531d8c239c4c09248b01b0e83d1b7a9546d2d59f778f51527c9ca53a1c99c79fa518b3b741a8d220fee337e38479aa5e7d6 SHA512 f0b669ffaa4b110f2c8eb24138b8300224ef670a18965da6db31faad9de1185991d1a74eb60e9f86b57d9c3ec5df7f230bc49a4d5ce87553ba845e1ac3f1be7e
diff --git a/dev-libs/librepo/librepo-1.17.1.ebuild b/dev-libs/librepo/librepo-1.17.1.ebuild
new file mode 100644
index 0000000000..2f617e6ef5
--- /dev/null
+++ b/dev-libs/librepo/librepo-1.17.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Repodata downloading library"
+HOMEPAGE="https://github.com/rpm-software-management/librepo"
+SRC_URI="https://github.com/rpm-software-management/librepo/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc gpgme test +zchunk"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.66:2
+	dev-libs/libxml2
+	dev-libs/openssl:=
+	>=net-misc/curl-7.52.0
+	gpgme? ( app-crypt/gpgme:1= )
+	!gpgme? ( >=app-arch/rpm-4.18.0 )
+	zchunk? ( >=app-arch/zchunk-0.9.11 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+	test? ( dev-libs/check )
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# respect temp directory during tests, bug #924463
+	sed -i "s|/tmp/|${T}/|" tests/testsys.h || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PYTHON=OFF
+		-DENABLE_SELINUX=OFF
+		-DUSE_GPGME=$(usex gpgme)
+		-DENABLE_DOCS=$(usex doc)
+		-DENABLE_TESTS=$(usex test)
+		-DWITH_ZCHUNK=$(usex zchunk)
+	)
+	cmake_src_configure
+}
-- 
cgit v1.2.3-65-gdbad