# Copyright 2020-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{7,8} )

inherit distutils-r1

DESCRIPTION="Sphinx extension that automatically documents argparse commands and options"
HOMEPAGE="https://pypi.org/project/sphinx-argparse/
	https://github.com/alex-rudakov/sphinx-argparse"
SRC_URI="https://github.com/alex-rudakov/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=""
RDEPEND="
	${DEPEND}
	dev-python/sphinx[${PYTHON_USEDEP}]
	dev-python/commonmark[${PYTHON_USEDEP}]
"

distutils_enable_tests pytest
# requires self to build own documentation
distutils_enable_sphinx docs dev-python/sphinx_rtd_theme dev-python/sphinx-argparse

python_prepare_all() {
	# test fails, skip it until a fix is found:
	# AssertionError: assert [{'action_groups': [{'description': None,\n    'options': [{'default': None,\n
	sed -i -e 's:test_parse_nested:_&:' \
		-e 's:test_parse_nested_traversal:_&:' \
			test/test_parser.py || die

	# needs test files in workdir to compile docs for some reason
	cp -r test "${WORKDIR}/test/" || die

	distutils-r1_python_prepare_all
}