aboutsummaryrefslogtreecommitdiff
blob: 63872934c6ab012365490470eff359b787cc7452 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
# Copyright 2019-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{7..9} )

inherit distutils-r1 desktop

DESCRIPTION="wallpaper manager for wlroots compositors"
HOMEPAGE="https://github.com/nwg-piotr/azote"

if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/nwg-piotr/azote"
else
	SRC_URI="https://github.com/nwg-piotr/azote/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64"
fi

LICENSE="GPL-3 BSD"
SLOT="0"
IUSE="simple-colorpicker imagemagick wayland X yaml"

RDEPEND="
	dev-cpp/gtkmm:3.0
	dev-python/pillow
	dev-python/pygobject:3=
	dev-python/send2trash
	simple-colorpicker? (
		X? (
			media-gfx/maim
			x11-misc/slop
		)
		wayland? (
			gui-apps/grim
			gui-apps/slurp
		)
	)
	imagemagick? (
		media-gfx/imagemagick[jpeg,png,svg,X?]
	)
	wayland? (
		gui-apps/swaybg
		gui-apps/wlr-randr
	)
	X? (
		media-gfx/feh
		x11-apps/xrandr
	)
	yaml? ( dev-python/pyyaml )
"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

python_install_all() {
	distutils-r1_python_install_all

	cd "${S}"

	dobin dist/azote
	domenu dist/azote.desktop

	insinto /usr/share/azote
	doins dist/azote.svg dist/indicator_{active,attention}.png
	insinto /usr/share/licenses/azote
	doins LICENSE-COLORTHIEF
}