Merge updates from master

4 files changed, 181 insertions, 0 deletions

diff --git a/games-util/lutris/lutris-0.5.0.1.ebuild b/games-util/lutris/lutris-0.5.0.1-r1.ebuild
index fca79a193ebf..d6cbb9e6644a 100644
--- a/games-util/lutris/lutris-0.5.0.1.ebuild
+++ b/games-util/lutris/lutris-0.5.0.1-r1.ebuild
@@ -34,6 +34,7 @@ RDEPEND="
 	dev-python/pygobject:3[${PYTHON_USEDEP}]
 	dev-python/python-evdev[${PYTHON_USEDEP}]
 	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
 	gnome-base/gnome-desktop[introspection]
 	media-sound/fluid-soundfont
 	net-libs/libsoup
diff --git a/net-libs/libsoup/Manifest b/net-libs/libsoup/Manifest
index 80172ce88b76..f7aa4020665a 100644
--- a/net-libs/libsoup/Manifest
+++ b/net-libs/libsoup/Manifest
@@ -1,2 +1,3 @@
 DIST libsoup-2.58.2.tar.xz 1815256 BLAKE2B 23c6e40f91a2dca13fcabe4fa3af7311874cbe06962c6cdc93d8d8d0a998d29cff9e7ce61190541b6114b4996d758b7c469b0354a6012856667e9541a78177cb SHA512 85af6fac87343bdd22312518402144d33916225f60d6fa158efdd84f7ee7ed1f9895989b3558f711c9aedc93cff35a4114ad79d6d2aa19c54cb326f162a4c7de
 DIST libsoup-2.62.3.tar.xz 1851780 BLAKE2B e3a3518f485d4ab1fe133f5b382d32e4b949e720005c4fdbbe963ba68030d5fcfb11deb5103843f47f221b540e96c5d5ea0f7c52f898617dca37d8df9faec669 SHA512 88354728b1da10288472c7380f166263b64d979df3e6e70ebdbc7b61f3c8eb1dc1205d5b1ead16243c6d304940a4dd4e3a9f3b2ce3e1422a1c5032220b16c73b
+DIST libsoup-2.64.2.tar.xz 1793440 BLAKE2B 77a41ad62e0e419711cb26f510b6c0ca09c0430300f72144a0d0563a24e24639d1ca430784051b8de279623193a273510d5c95de6edb4a54a3aee0bd7903d9cd SHA512 c001495be4e1eafd169b904431b22e961b52f5a3202f2e75b0657281cbfd91153148765bd95378bba3e85a66d7eaca428750641f20c07ca3232d1f9bdabdc90f
diff --git a/net-libs/libsoup/libsoup-2.64.2.ebuild b/net-libs/libsoup/libsoup-2.64.2.ebuild
new file mode 100644
index 000000000000..be2bc815aed0
--- /dev/null
+++ b/net-libs/libsoup/libsoup-2.64.2.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_3,3_4,3_5,3_6} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 multilib-minimal python-any-r1 vala
+
+DESCRIPTION="An HTTP library implementation in C"
+HOMEPAGE="https://wiki.gnome.org/Projects/libsoup"
+
+LICENSE="LGPL-2+"
+SLOT="2.4"
+
+IUSE="debug gssapi +introspection samba ssl test +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
+	>=dev-db/sqlite-3.8.2:3[${MULTILIB_USEDEP}]
+	>=net-libs/libpsl-0.20.0[${MULTILIB_USEDEP}]
+	>=net-libs/glib-networking-2.38.2[ssl?,${MULTILIB_USEDEP}]
+	gssapi? ( virtual/krb5[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
+	samba? ( net-fs/samba )
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.20
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	test? ( >=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}] )
+	vala? ( $(vala_depend) )
+"
+#	test? (	www-servers/apache[ssl,apache2_modules_auth_digest,apache2_modules_alias,apache2_modules_auth_basic,
+#		apache2_modules_authn_file,apache2_modules_authz_host,apache2_modules_authz_user,apache2_modules_dir,
+#		apache2_modules_mime,apache2_modules_proxy,apache2_modules_proxy_http,apache2_modules_proxy_connect]
+#		dev-lang/php[apache2,xmlrpc]
+#		net-misc/curl
+#		net-libs/glib-networking[ssl])"
+
+src_prepare() {
+	if ! use test; then
+		# don't waste time building tests (bug #226271)
+		sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
+			|| die "sed failed"
+	fi
+
+	# FIXME: workaround upstream not respecting --without-apache-httpd
+	sed -e '/check: start-httpd/d' \
+		-i tests/Makefile.am tests/Makefile.in || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# FIXME: we need addpredict to workaround bug #324779 until
+	# root cause (bug #249496) is solved
+	addpredict /usr/share/snmp/mibs/.index
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	# Disable apache tests until they are usable on Gentoo, bug #326957
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		--disable-static \
+		--disable-tls-check \
+		--without-gnome \
+		--without-apache-httpd \
+		$(usex debug --enable-debug=yes ' ') \
+		$(multilib_native_use_with gssapi) \
+		$(multilib_native_use_enable introspection) \
+		$(multilib_native_use_enable vala) \
+		$(use_with samba ntlm-auth '${EPREFIX}'/usr/bin/ntlm_auth)
+
+	if multilib_is_native_abi; then
+		# fix gtk-doc
+		ln -s "${S}"/docs/reference/html docs/reference/html || die
+	fi
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
diff --git a/sys-fs/squashfs-tools/squashfs-tools-4.3_p11-r1.ebuild b/sys-fs/squashfs-tools/squashfs-tools-4.3_p11-r1.ebuild
new file mode 100644
index 000000000000..b0c96a39261a
--- /dev/null
+++ b/sys-fs/squashfs-tools/squashfs-tools-4.3_p11-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="tools to create and extract Squashfs filesystems"
+HOMEPAGE="http://squashfs.sourceforge.net"
+SRC_URI="
+	mirror://sourceforge/squashfs/squashfs${PV/_p*}.tar.gz
+	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV/_p*}-${PV/*_p}.debian.tar.xz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="debug lz4 lzma lzo static xattr +xz zstd"
+
+LIB_DEPEND="
+	sys-libs/zlib[static-libs(+)]
+	!xz? ( !lzo? ( sys-libs/zlib[static-libs(+)] ) )
+	lz4? ( app-arch/lz4[static-libs(+)] )
+	lzma? ( app-arch/xz-utils[static-libs(+)] )
+	lzo? ( dev-libs/lzo[static-libs(+)] )
+	xattr? ( sys-apps/attr[static-libs(+)] )
+	xz? ( app-arch/xz-utils[static-libs(+)] )
+	zstd? ( app-arch/zstd[static-libs(+)] )
+"
+RDEPEND="
+	!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
+"
+DEPEND="
+	${RDEPEND}
+	static? ( ${LIB_DEPEND} )
+"
+PATCHES=(
+	"${FILESDIR}"/${P/_p*}-sysmacros.patch
+	"${FILESDIR}"/${P/_p*}-aligned-data.patch
+	"${FILESDIR}"/${P/_p*}-local-cve-fix.patch
+	"${FILESDIR}"/${P/_p*}-mem-overflow.patch
+	"${FILESDIR}"/${P/_p*}-extmatch.patch
+	"${FILESDIR}"/${P/_p*}-musl.patch
+)
+
+S="${WORKDIR}/squashfs${PV/_p*}/${PN}"
+
+src_prepare() {
+	mv "${WORKDIR}"/debian/patches/0016-remove-frag_deflator_thread.patch "${WORKDIR}"/ || die
+	eapply -p2 "${WORKDIR}"/debian/patches/*.patch
+	eapply -p2 ${PATCHES[@]}
+	eapply_user
+}
+
+use10() { usex $1 1 0 ; }
+
+src_configure() {
+	# restore GNU89 inline semantics to
+	# emit function symbols, bug 595290
+	append-cflags -std=gnu89
+
+	# set up make command line variables in EMAKE_SQUASHFS_CONF
+	EMAKE_SQUASHFS_CONF=(
+		LZMA_XZ_SUPPORT=$(use10 lzma)
+		LZO_SUPPORT=$(use10 lzo)
+		LZ4_SUPPORT=$(use10 lz4)
+		XATTR_SUPPORT=$(use10 xattr)
+		XZ_SUPPORT=$(use10 xz)
+		ZSTD_SUPPORT=$(use10 zstd)
+	)
+
+	tc-export CC
+	use debug && append-cppflags -DSQUASHFS_TRACE
+	use static && append-ldflags -static
+}
+
+src_compile() {
+	emake "${EMAKE_SQUASHFS_CONF[@]}"
+}
+
+src_install() {
+	dobin mksquashfs unsquashfs
+	cd ..
+	dodoc CHANGES PERFORMANCE.README pseudo-file.example README* OLD-READMEs/*
+	doman "${WORKDIR}"/debian/manpages/*.[0-9]
+}