From 8e526a4c11387c99eab0ddf17d8e103f15038b3e Mon Sep 17 00:00:00 2001
From: Austin English <wizardedit@gentoo.org>
Date: Thu, 7 Sep 2017 12:47:14 -0500
Subject: games-strategy/boswars: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082
Package-Manager: Portage-2.3.6, Repoman-2.3.2
---
 games-strategy/boswars/boswars-2.7-r2.ebuild       | 70 ++++++++++++++++++++++
 .../boswars/files/boswars-2.7-gentoo.patch         |  4 +-
 .../boswars/files/boswars-2.7-scons-blows.patch    |  4 +-
 3 files changed, 74 insertions(+), 4 deletions(-)
 create mode 100644 games-strategy/boswars/boswars-2.7-r2.ebuild

diff --git a/games-strategy/boswars/boswars-2.7-r2.ebuild b/games-strategy/boswars/boswars-2.7-r2.ebuild
new file mode 100644
index 000000000000..e47f414ef946
--- /dev/null
+++ b/games-strategy/boswars/boswars-2.7-r2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils scons-utils
+
+DESCRIPTION="Futuristic real-time strategy game"
+HOMEPAGE="http://www.boswars.org/"
+SRC_URI="http://www.boswars.org/dist/releases/${P}-src.tar.gz
+	https://dev.gentoo.org/~hasufell/distfiles/${P}-fixed-images-for-libpng-1.6.tar.xz
+	mirror://gentoo/bos.png"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="dev-lang/lua:0
+	media-libs/libogg
+	media-libs/libpng:0
+	media-libs/libsdl[opengl,sound,video]
+	media-libs/libtheora
+	media-libs/libvorbis
+	virtual/opengl
+	x11-libs/libX11"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${P}-src
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+	"${FILESDIR}"/${P}-scons-blows.patch
+)
+
+src_unpack() {
+	default
+	# bug 475764
+	cp -dRp ${P}-fixed-images-for-libpng-1.6/* ${P}-src/ \
+		|| die "copying fixed images failed!"
+}
+
+src_prepare() {
+	default
+
+	rm -f doc/{README-SDL.txt,guichan-copyright.txt} || die
+
+	sed -i \
+		-e "s:@GENTOO_DATADIR@:/usr/share/${PN}:" \
+		engine/include/stratagus.h \
+		|| die
+	sed -i \
+		-e "/-O2/s:-O2.*math:${CXXFLAGS} -Wall:" \
+		SConstruct \
+		|| die
+}
+
+src_compile() {
+	escons || die
+}
+
+src_install() {
+	newbin build/${PN}-release ${PN}
+	insinto /usr/share/${PN}
+	doins -r campaigns graphics intro languages maps patches scripts sounds units
+	newicon "${DISTDIR}"/bos.png ${PN}.png
+	make_desktop_entry ${PN} "Bos Wars"
+	# COPYRIGHT.txt is referenced by the html
+	dodoc CHANGELOG COPYRIGHT.txt README.txt
+	dodoc -r doc/*
+}
diff --git a/games-strategy/boswars/files/boswars-2.7-gentoo.patch b/games-strategy/boswars/files/boswars-2.7-gentoo.patch
index 9459c77d89bc..a005f6f93ad0 100644
--- a/games-strategy/boswars/files/boswars-2.7-gentoo.patch
+++ b/games-strategy/boswars/files/boswars-2.7-gentoo.patch
@@ -1,5 +1,5 @@
-diff -ru boswars-2.6.1-src.orig/engine/include/stratagus.h boswars-2.6.1-src/engine/include/stratagus.h
---- boswars-2.6.1-src.orig/engine/include/stratagus.h	2010-04-11 08:12:18.000000000 -0400
+diff -ru boswars-2.6.1-src/engine/include/stratagus.h boswars-2.6.1-src/engine/include/stratagus.h
+--- boswars-2.6.1-src/engine/include/stratagus.h	2010-04-11 08:12:18.000000000 -0400
 +++ boswars-2.6.1-src/engine/include/stratagus.h	2010-05-22 02:33:50.021377764 -0400
 @@ -133,7 +133,7 @@
  --  General
diff --git a/games-strategy/boswars/files/boswars-2.7-scons-blows.patch b/games-strategy/boswars/files/boswars-2.7-scons-blows.patch
index 0a7029df4971..1d2c04cc4f1b 100644
--- a/games-strategy/boswars/files/boswars-2.7-scons-blows.patch
+++ b/games-strategy/boswars/files/boswars-2.7-scons-blows.patch
@@ -1,5 +1,5 @@
---- SConstruct.orig	2010-11-19 21:09:45.724976603 -0500
-+++ SConstruct	2010-11-19 21:11:05.723197985 -0500
+--- a/SConstruct	2010-11-19 21:09:45.724976603 -0500
++++ b/SConstruct	2010-11-19 21:11:05.723197985 -0500
 @@ -22,6 +22,7 @@
  ##
  
-- 
cgit v1.2.3-65-gdbad