From e45d5c13978dbbe8a419ec6d2d761aa8ed20c710 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sat, 3 Nov 2018 11:38:36 +0100
Subject: dev-cpp/libjson-rpc-cpp: Switch to dev-cpp/catch-2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../libjson-rpc-cpp-1.1.1-r1.ebuild                | 67 ++++++++++++++++++++++
 .../libjson-rpc-cpp/libjson-rpc-cpp-9999.ebuild    |  4 +-
 2 files changed, 69 insertions(+), 2 deletions(-)
 create mode 100644 dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.1-r1.ebuild

(limited to 'dev-cpp')

diff --git a/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.1-r1.ebuild b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.1-r1.ebuild
new file mode 100644
index 000000000000..fbf180d4cf2d
--- /dev/null
+++ b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.1-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="JSON-RPC (1.0 & 2.0) framework for C++"
+HOMEPAGE="https://github.com/cinemast/libjson-rpc-cpp"
+SRC_URI="https://github.com/cinemast/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +http-client +http-server redis-client redis-server +stubgen test"
+
+RDEPEND="
+	dev-libs/jsoncpp:=
+	http-client? ( net-misc/curl:= )
+	http-server? ( net-libs/libmicrohttpd:= )
+	redis-client? ( dev-libs/hiredis:= )
+	redis-server? ( dev-libs/hiredis:= )
+	stubgen? ( dev-libs/argtable:= )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( >=dev-cpp/catch-2 )"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DHTTP_CLIENT=$(usex http-client)
+		-DHTTP_SERVER=$(usex http-server)
+		-DREDIS_CLIENT=$(usex redis-client)
+		-DREDIS_SERVER=$(usex redis-server)
+		# they have no deps
+		-DTCP_SOCKET_CLIENT=ON
+		-DTCP_SOCKET_SERVER=ON
+		-DUNIX_DOMAIN_SOCKET_CLIENT=ON
+		-DUNIX_DOMAIN_SOCKET_SERVER=ON
+		# they are not installed
+		-DCOMPILE_EXAMPLES=OFF
+		-DCOMPILE_STUBGEN=$(usex stubgen)
+		-DCOMPILE_TESTS=$(usex test)
+		-DCATCH_INCLUDE_DIR="${EPREFIX}/usr/include/catch2"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	use doc && emake -C "${BUILD_DIR}" doc
+}
+
+src_test() {
+	# Tests fail randomly when run in parallel
+	local MAKEOPTS=-j1
+	cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/doc/html
+}
diff --git a/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-9999.ebuild b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-9999.ebuild
index 0e617416361e..1daad1e754b0 100644
--- a/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-9999.ebuild
+++ b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-9999.ebuild
@@ -25,7 +25,7 @@ RDEPEND="
 	stubgen? ( dev-libs/argtable:= )"
 DEPEND="${RDEPEND}
 	doc? ( app-doc/doxygen )
-	test? ( <dev-cpp/catch-2 )"
+	test? ( >=dev-cpp/catch-2 )"
 
 RESTRICT="!test? ( test )"
 
@@ -44,7 +44,7 @@ src_configure() {
 		-DCOMPILE_EXAMPLES=OFF
 		-DCOMPILE_STUBGEN=$(usex stubgen)
 		-DCOMPILE_TESTS=$(usex test)
-		-DCATCH_INCLUDE_DIR="${EPREFIX}/usr/include/catch"
+		-DCATCH_INCLUDE_DIR="${EPREFIX}/usr/include/catch2"
 	)
 
 	cmake-utils_src_configure
-- 
cgit v1.2.3-65-gdbad