From 539629f1be1e6353041fbd1b1e895a307f99ae57 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Wed, 22 Feb 2023 05:53:30 +0100
Subject: dev-python/oslo-config: Bump to 9.1.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/oslo-config/Manifest                 |  1 +
 dev-python/oslo-config/oslo-config-9.1.1.ebuild | 59 +++++++++++++++++++++++++
 2 files changed, 60 insertions(+)
 create mode 100644 dev-python/oslo-config/oslo-config-9.1.1.ebuild

(limited to 'dev-python/oslo-config')

diff --git a/dev-python/oslo-config/Manifest b/dev-python/oslo-config/Manifest
index 3ea87a78554b..21b8e1f23654 100644
--- a/dev-python/oslo-config/Manifest
+++ b/dev-python/oslo-config/Manifest
@@ -1 +1,2 @@
 DIST oslo.config-9.1.0.tar.gz 161010 BLAKE2B 58edfd3218feb51b993eb6b23fa8ea6f0464d5210f35881c1c509c672cce961f62972634d4922aed7105163d4d0f90f6a34438009016d3e2bb43dfd8c4bdbf75 SHA512 768ee64c9bbfd8b23de7a3b15d46e5065356769f2dd4bc4871ad3cb8c56febced57515c89a8c530b6ba7ae347eff826b7c4f4c12aa80daf3325b0143dad1045a
+DIST oslo.config-9.1.1.tar.gz 160964 BLAKE2B 180b76d9425b9be72dac22379618b69265ab7016044ac81ed826134036aa988d867882116a50597df62b702bfff4460ac17e7c1d435ff9a1f0028a2ff64b7a2f SHA512 820da069642a663cad0787ee4e100720dcc9870faeaa208c8aa5be5f3c6bbbf1e5e3d2cb8c5d86765fd4114744e2fd1a00902d79200ddeba5fcec2ed61405e4e
diff --git a/dev-python/oslo-config/oslo-config-9.1.1.ebuild b/dev-python/oslo-config/oslo-config-9.1.1.ebuild
new file mode 100644
index 000000000000..c3a45e37e97c
--- /dev/null
+++ b/dev-python/oslo-config/oslo-config-9.1.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Oslo Configuration API"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.config/
+	https://github.com/openstack/oslo.config/
+	https://pypi.org/project/oslo.config/
+"
+SRC_URI="$(pypi_sdist_url --no-normalize "${PN/-/.}")"
+S=${WORKDIR}/${P/-/.}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.5.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# broken by some dep upgrade
+	sed -i -e '/DeprecationWarningTestsNoOsloLog/,$d' \
+		oslo_config/tests/test_cfg.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x COLUMNS=80
+	eunittest -b
+}
-- 
cgit v1.2.3-65-gdbad