From ec069d87897015df9da8516887c79403c092c339 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Sat, 6 May 2017 10:56:05 +0200
Subject: net-analyzer/hydra: Version bump (bug #617540 by Anton Bolshakov).

Package-Manager: Portage-2.3.5, Repoman-2.3.2
---
 net-analyzer/hydra/Manifest         |   1 +
 net-analyzer/hydra/hydra-8.5.ebuild | 102 ++++++++++++++++++++++++++++++++++++
 2 files changed, 103 insertions(+)
 create mode 100644 net-analyzer/hydra/hydra-8.5.ebuild

(limited to 'net-analyzer')

diff --git a/net-analyzer/hydra/Manifest b/net-analyzer/hydra/Manifest
index 01de2f14ba9a..0be0acb46944 100644
--- a/net-analyzer/hydra/Manifest
+++ b/net-analyzer/hydra/Manifest
@@ -1,2 +1,3 @@
 DIST hydra-8.1.tar.gz 559031 SHA256 e4bc2fd11f97a8d985a38a31785c86d38cc60383e47a8f4a5c436351e5135f19 SHA512 7608dd365865e5976bea446faedaad9f0334e7572fd0ee47a601c471471fc7c8a922c7114f4df08705b34b29144d3a6552e66148adf6b0f92c67301119c94959 WHIRLPOOL b1555fe1a8257c88f8f5c110fce1d06834eb6dadad394b61e2a90c3289b8fdd117944da160871003b1583aefb81a02d5c49a653e8de7d3adcd07917ae760c83c
 DIST hydra-8.4.tar.gz 1205609 SHA256 482846580888f54e000bb125e263a65c32fa28ba86c9d4012371cf55c3bdc140 SHA512 62c53f1725eb5b965d16d293cd90ab5e74779eba8fe2e2ab9094f51851fa24acfd74574f509a7914af8254e43197d803cca6b41eace3557d9599d79d695f6a48 WHIRLPOOL aecc31645e7775662e32b766baa942e92e31143e5b6fbe64620ee85179288dc60f3ada477b4605444769c9e76c17d94835db5f3651af409d5562a2e8971279ef
+DIST hydra-8.5.tar.gz 1214640 SHA256 557ab284f877aa6c8a26f7491c0373a84836593e5e0ca141b327035e7937dd6d SHA512 0b462074a5556a53eb3135da7d4c3cafac5448645fa6020f9a86caea04f0e35ebead32e63db80ba8e680a3b14ff7f6a125553653e776c8e54e9caf923c0da0ec WHIRLPOOL cbd6273f2408cebe943e6f231b1c2e8e34d4e091d96ef4c86a6015a1e6df003442b1d025d6f7e8f83f12d87376c300f08ba8b785a3a0bdfa0d1785e19362b0de
diff --git a/net-analyzer/hydra/hydra-8.5.ebuild b/net-analyzer/hydra/hydra-8.5.ebuild
new file mode 100644
index 000000000000..62d90db2a0d6
--- /dev/null
+++ b/net-analyzer/hydra/hydra-8.5.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Advanced parallized login hacker"
+HOMEPAGE="https://www.thc.org/thc-hydra/"
+SRC_URI="https://www.thc.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="firebird gtk idn libressl mysql ncp oracle pcre postgres ssl subversion"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	sys-libs/ncurses:=
+	firebird? ( dev-db/firebird )
+	gtk? (
+		dev-libs/atk
+		dev-libs/glib:2
+		x11-libs/gdk-pixbuf:2
+		x11-libs/gtk+:2
+	)
+	idn? ( net-dns/libidn )
+	mysql? ( virtual/mysql )
+	ncp? ( net-fs/ncpfs )
+	oracle? ( dev-db/oracle-instantclient-basic )
+	pcre? ( dev-libs/libpcre )
+	postgres? ( dev-db/postgresql:* )
+	ssl? ( >=net-libs/libssh-0.4.0 )
+	subversion? ( dev-vcs/subversion )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-8.4-configure.patch
+)
+
+src_prepare() {
+	default
+
+	# None of the settings in Makefile.unix are useful to us
+	: > Makefile.unix
+
+	sed -i \
+		-e 's:|| echo.*$::' \
+		-e '/\t-$(CC)/s:-::' \
+		-e '/^OPTS/{s|=|+=|;s| -O3||}' \
+		-e '/ -o /s:$(OPTS):& $(LDFLAGS):g' \
+		Makefile.am || die
+}
+
+src_configure() {
+	export OPTS="${CFLAGS}"
+
+	if ! use subversion; then
+		sed -i 's/-lsvn_client-1 -lapr-1 -laprutil-1 -lsvn_subr-1//;s/-DLIBSVN//' configure || die
+	fi
+
+	if ! use mysql; then
+		sed -i 's/-lmysqlclient//;s/-DLIBMYSQLCLIENT//' configure || die
+	fi
+
+	# Linking against libtinfo might be enough here but pkg-config --libs tinfo
+	# would require a USE=tinfo flag and recent linkers should drop libcurses
+	# as needed
+	sed -i \
+		-e 's|-lcurses|'"$( $(tc-getPKG_CONFIG) --libs ncurses)"'|g' \
+		configure || die
+
+	# Note: despite the naming convention, the top level script is not an
+	# autoconf-based script.
+	export NCP_PATH=$(usex ncp /usr/$(get_libdir) '')
+	export NCP_IPATH=$(usex ncp /usr/include '')
+	sh configure \
+		--prefix=/usr \
+		--nostrip \
+		$(use gtk && echo --disable-xhydra) \
+			|| die
+
+	if use gtk ; then
+		cd hydra-gtk && \
+		econf
+	fi
+}
+
+src_compile() {
+	tc-export CC
+	emake XLIBPATHS=''
+	use gtk && emake -C hydra-gtk
+}
+
+src_install() {
+	dobin hydra pw-inspector
+	use gtk && dobin hydra-gtk/src/xhydra
+	dodoc CHANGES README
+}
-- 
cgit v1.2.3-65-gdbad