From f8c8d4e4775703959ef7a378029be7f90f5c87bf Mon Sep 17 00:00:00 2001
From: Eray Aslan <eras@gentoo.org>
Date: Thu, 10 Dec 2015 16:16:12 +0200
Subject: net-mail/mailutils: version bump to 2.99.99

Package-Manager: portage-2.2.26
---
 net-mail/mailutils/Manifest                 |   1 +
 net-mail/mailutils/mailutils-2.99.99.ebuild | 127 ++++++++++++++++++++++++++++
 2 files changed, 128 insertions(+)
 create mode 100644 net-mail/mailutils/mailutils-2.99.99.ebuild

(limited to 'net-mail')

diff --git a/net-mail/mailutils/Manifest b/net-mail/mailutils/Manifest
index ea64dd97e74b..87cf7eac5bbf 100644
--- a/net-mail/mailutils/Manifest
+++ b/net-mail/mailutils/Manifest
@@ -1 +1,2 @@
 DIST mailutils-2.99.98.tar.xz 2505252 SHA256 62e2c28aed77e451e05ed15e68b5abc3932bcc3d2d6caf9b4a6864258c6a7b1a SHA512 fc20d97b3eed0f0ff7f1d7885e59f8de6ffd5b4646cd06c3636bda4a6bc9f7a0d5acdc7bb3bb573cdc80d63dfdc0be6464033ef2f6d88514bd2190f6611a1083 WHIRLPOOL c0f6f4f9dc2d60074c06a6c8f604fa4d92df4dafd6e205df8c360e97663e96c9b64a02aab9af7eab0659abc39e8aed70bbb0761b7d5a21b5873beabbcd409030
+DIST mailutils-2.99.99.tar.xz 2796000 SHA256 fd7743673e81ceb864e0c5876f9304616ca3759d69c662c27d6e093a9919f31d SHA512 a65f9cde0732f27cdea69385b72806e0f44c774006ad7613039644e7a822f26789c46bb06127ca0fa13dbc3e4ad0382e0a7bee6124e240ff58b394ba8a125bfb WHIRLPOOL 7790095392c7111ed858c547145ceb70687c8dae11c1b7cdc4df319ebe28ea07d941d7936d20d6a4e191418f22914d1ef65da194e2e7573f53688a4ce82d9325
diff --git a/net-mail/mailutils/mailutils-2.99.99.ebuild b/net-mail/mailutils/mailutils-2.99.99.ebuild
new file mode 100644
index 000000000000..34d0078adb60
--- /dev/null
+++ b/net-mail/mailutils/mailutils-2.99.99.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools eutils flag-o-matic python-single-r1 toolchain-funcs
+
+DESCRIPTION="A useful collection of mail servers, clients, and filters"
+HOMEPAGE="https://www.gnu.org/software/mailutils/mailutils.html"
+#SRC_URI="mirror://gnu/mailutils/${P}.tar.xz"
+SRC_URI="mirror://gnu-alpha/mailutils/${P}.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~x86 ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="berkdb bidi +clients gdbm sasl guile ipv6 kerberos ldap mysql nls pam postgres
+python servers ssl static-libs +threads tcpd tokyocabinet"
+
+# Drop the libtool dep once libltdl goes stable.
+RDEPEND="!mail-client/nmh
+	!mail-filter/libsieve
+	!mail-client/mailx
+	!mail-client/nail
+	sys-libs/ncurses:0=
+	sys-libs/readline:*
+	|| ( dev-libs/libltdl:0 <sys-devel/libtool-2.4.3-r2:2 )
+	virtual/mta
+	berkdb? ( sys-libs/db:* )
+	bidi? ( dev-libs/fribidi )
+	gdbm? ( sys-libs/gdbm )
+	guile? ( dev-scheme/guile:* )
+	kerberos? ( virtual/krb5 )
+	ldap? ( net-nds/openldap )
+	mysql? ( virtual/mysql )
+	nls? ( sys-devel/gettext )
+	pam? ( virtual/pam )
+	postgres? ( dev-db/postgresql:* )
+	python? ( ${PYTHON_DEPS} )
+	sasl? ( virtual/gsasl )
+	ssl? ( net-libs/gnutls )
+	tcpd? ( sys-apps/tcp-wrappers )
+	tokyocabinet? ( dev-db/tokyocabinet )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable bytecompilation of Python modules.
+	echo "#!/bin/sh" > build-aux/py-compile
+	epatch "${FILESDIR}/${PN}-2.99.98-readline-6.3.patch" #503954
+	if use mysql; then
+		sed -i -e /^INCLUDES/"s:$:$(mysql_config --include):" \
+			sql/Makefile.am || die
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	# maildir is the Gentoo default
+	# but fails tests. So set it in config file instead.
+	econf MU_DEFAULT_SCHEME=maildir \
+		CURSES_LIBS="$($(tc-getPKG_CONFIG) --libs ncurses)" \
+		$(use_with berkdb berkeley-db) \
+		$(use_with bidi fribidi) \
+		$(use_enable ipv6) \
+		$(use_with gdbm) \
+		$(use_with sasl gsasl) \
+		$(use_with guile) \
+		$(use_with kerberos gssapi) \
+		$(use_with ldap) \
+		$(use_with mysql) \
+		$(use_enable nls) \
+		$(use_enable pam) \
+		$(use_with postgres) \
+		$(use_enable python) \
+		$(use_with ssl gnutls) \
+		$(use_enable static-libs static) \
+		$(use_enable threads pthread) \
+		$(use_with tokyocabinet) \
+		$(use_enable servers build-servers) \
+		$(use_enable clients build-clients) \
+		--with-mail-spool=/var/spool/mail \
+		--with-readline \
+		--enable-sendmail \
+		--disable-debug \
+		--disable-rpath
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	doins "${FILESDIR}/mailutils.rc"
+	keepdir /etc/mailutils.d/
+	insinto /etc/mailutils.d
+	doins "${FILESDIR}/mail"
+
+	if use python; then
+		python_optimize
+		if use static-libs; then
+			rm -r "${D}$(python_get_sitedir)/mailutils"/*.{a,la} || die
+		fi
+	fi
+
+	if use servers; then
+		newinitd "${FILESDIR}"/imap4d.initd imap4d
+		newinitd "${FILESDIR}"/pop3d.initd pop3d
+		newinitd "${FILESDIR}"/comsatd.initd comsatd
+	fi
+
+	dodoc AUTHORS ChangeLog NEWS README* THANKS TODO
+
+	# compatibility link
+	use clients && dosym /usr/bin/mail /bin/mail
+
+	use static-libs || find "${D}" -name "*.la" -delete
+}
-- 
cgit v1.2.3-65-gdbad