blob: 27a8e536210601555850c3616dd54c737d369502 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit flag-o-matic qmake-utils toolchain-funcs
DESCRIPTION="Visualisation and processing of experimental and simulated NMR spectra"
HOMEPAGE="http://sourceforge.net/projects/gsim/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="cpu_flags_x86_sse3 emf opengl"
REQUIRED_USE="cpu_flags_x86_sse3"
RDEPEND="
dev-cpp/muParser
media-libs/freetype
sci-libs/libcmatrix
sci-libs/minuit
virtual/blas
dev-qt/qtsvg:4
emf? ( media-libs/libemf )
opengl? ( dev-qt/qtopengl:4 )"
DEPEND="${RDEPEND}
virtual/pkgconfig"
PATCHES=(
"${FILESDIR}/${P}-build.conf.patch"
)
DOCS="release.txt README_GSIM.* quickstart.* changes.log programming.*"
src_prepare() {
edos2unix ${PN}.pro
default
# C{,XX}FLAGS need to explicitly enable SSE3 support
# bug #555972
filter-flags -mno-sse3
append-cflags -msse3
append-cxxflags -msse3
cat >> build.conf <<- EOF
INCLUDEPATH += "${EPREFIX}/usr/include/libcmatrixR3/" \
"${EPREFIX}/usr/include/Minuit2" \
"${EPREFIX}/usr/include"
LIBS += -lcmatrix -lMinuit2 -lmuparser $($(tc-getPKG_CONFIG) --libs cblas)
EOF
use opengl && echo "CONFIG+=use_opengl" >> build.conf
if use emf; then
cat >> build.conf <<- EOF
CONFIG+=use_emf
DEFINES+=USE_EMF_OUTPUT
LIBS += -L\"${EPREFIX}/usr/include/libEMF\" -lEMF
EOF
fi
sed \
-e "s:quickstart.pdf:../share/doc/${PF}/quickstart.pdf:g" \
-e "s:README_GSIM.pdf:../share/doc/${PF}/README_GSIM.pdf:g" \
-i mainform.h || die
}
src_configure() {
eqmake4 ${PN}.pro
}
src_install() {
default
dobin ${PN}
insinto /usr/share/${PN}
doins -r images ${PN}.ico
insinto /usr/share/${PN}/ui
doins *.ui
}
|
GitWeb