1 files changed, 50 insertions, 0 deletions
diff --git a/games-engines/freesci/freesci-0.6.4-r2.ebuild b/games-engines/freesci/freesci-0.6.4-r2.ebuild
new file mode 100644
index 00000000..fe1f18c4
--- /dev/null
+++ b/games-engines/freesci/freesci-0.6.4-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors and Martin V\"ath
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit desktop
+RESTRICT="mirror"
+
+DESCRIPTION="Sierra script interpreter for your old Sierra adventures"
+HOMEPAGE="http://freesci.linuxgames.com/"
+SRC_URI="http://www-plan.cs.colorado.edu/creichen/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86"
+IUSE="X ggi sdl"
+
+DEPEND="media-libs/alsa-lib
+	X? (
+		x11-libs/libX11
+		x11-libs/libXrender
+		x11-libs/libXext
+	)
+	ggi? ( media-libs/libggi )
+	sdl? ( media-libs/libsdl )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	sed -i \
+		-e "/^SUBDIRS =/s:desktop src conf debian:src:" \
+		Makefile.in \
+		|| die "sed failed"
+	eapply -p0 "${FILESDIR}"/${P}-glibc2.10.patch
+	eapply "${FILESDIR}"/inline.patch
+	default
+}
+
+src_configure() {
+	econf \
+		--with-Wall \
+		--without-directfb \
+		$(use_with X x) \
+		$(use_with ggi) \
+		$(use_with sdl)
+}
+
+src_install() {
+	default
+	doicon desktop/${PN}.png
+	make_desktop_entry ${PN} FreeSCI
+}