Add botocore-1.10.4

4 files changed, 109 insertions, 0 deletions

diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
new file mode 100644
index 0000000..7a44805
--- /dev/null
+++ b/dev-python/botocore/Manifest
@@ -0,0 +1,4 @@
+AUX 1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch 1056 BLAKE2B ecdf805cd61e337d4152d56952aeb8b78bfdd871b4da060d025ca4e3f974b3b7a907eee71ce6de1bc6cff8130fa81391aeaa2c5537b1baf159ce23500908a5f4 SHA512 c3be1a6457990168c759f03b24de8f78242b9c06f189553e416ce75fee6a77dce68967a551dfd83e1be096db9baeca019b75526c4886c672eca35282e307f229
+DIST botocore-1.10.4.tar.gz 4328833 BLAKE2B e4c3b3a64a5dce5cfea54c13cba9a17d0d5f86817cca55bfacc29afa66f5242167382c256ef724ca8316c061fda4af7e3d8de763b079f567bf6e23a3bc6c2e75 SHA512 7063334f74dd7e90dc362976acc240ddc350d40b055c7ebd9782d3e8c6a99da4085a008d17902a8688bc3ddedcc5a5ce1b5c1c921ac25837943fc0812fb3194c
+EBUILD botocore-1.10.4.ebuild 1692 BLAKE2B b79eb5ef159f20927b376b8b60f1155f81e8acd1e3ef03f07249c013572892aa57daf6b8541097d803673141dddcef4d64ddcd3d8e1029edd467655168cace36 SHA512 f16ad1eb712af905ac1473c9e2b771af4717455f307aece2a6785b091b880e28878541ab9b10726998aa485f0a2e8a6e10c37af0bc35a07a307315ec377b5d9e
+MISC metadata.xml 375 BLAKE2B 562696aff0128b74dc4c2c0767fe03d53ae116cbc4fdb3a8649e36a8c689dcbd2a90bb5f46dcfa6a3cd71c9150f923281100ec098fe2212dfffa96d74e472d3f SHA512 c369567feea497a744245642a9a307b2a2ec06035fffc3b9b72d9f7ee9fe2f342d62cd1d06a668b47ac1b3187fc28845bcf3c220d942cfb2ac89f72809fc4a86
diff --git a/dev-python/botocore/botocore-1.10.4.ebuild b/dev-python/botocore/botocore-1.10.4.ebuild
new file mode 100644
index 0000000..447e982
--- /dev/null
+++ b/dev-python/botocore/botocore-1.10.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_4 python3_5 python3_6 )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3."
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="doc test"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	>=dev-python/docutils-0.10[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	<dev-python/jmespath-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	<dev-python/python-dateutil-2.7.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/guzzle_sphinx_theme-0.7.10[${PYTHON_USEDEP}]
+		<dev-python/guzzle_sphinx_theme-0.8[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.3[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.7[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=( "${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch" )
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	PYTHONPATH="${BUILD_DIR}/lib" nosetests -v tests/unit || die "unit tests failed under ${EPYTHON}"
+	PYTHONPATH="${BUILD_DIR}/lib" nosetests -v tests/functional || die "functional tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/botocore/files/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch b/dev-python/botocore/files/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch
new file mode 100644
index 0000000..49fd3ad
--- /dev/null
+++ b/dev-python/botocore/files/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch
@@ -0,0 +1,32 @@
+From 78077a5e80c9ad5f909037a48100481ddfedc6b2 Mon Sep 17 00:00:00 2001
+From: Andrey Utkin <andrey_utkin@gentoo.org>
+Date: Wed, 13 Dec 2017 01:50:03 +0000
+Subject: [PATCH] tests: pass all env vars to cmd-runner
+
+cmd-runner was started with no environment variables inherited.
+This breaks tests when run with custom PYTHONPATH, which is useful for
+testing botocore while not being installed in standard locations.
+
+One case when this is important is performing tests before installing
+the package in Gentoo Linux.
+
+Link: https://bugs.gentoo.org/640726
+---
+ tests/__init__.py | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/tests/__init__.py b/tests/__init__.py
+index 74a2e4de..fa0b819b 100644
+--- a/tests/__init__.py
++++ b/tests/__init__.py
+@@ -145,6 +145,7 @@ class BaseClientDriverTest(unittest.TestCase):
+         if self.INJECT_DUMMY_CREDS:
+             env = {'AWS_ACCESS_KEY_ID': 'foo',
+                    'AWS_SECRET_ACCESS_KEY': 'bar'}
++        env.update(os.environ)
+         self.driver.start(env=env)
+ 
+     def cmd(self, *args):
+-- 
+2.15.1
+
diff --git a/dev-python/botocore/metadata.xml b/dev-python/botocore/metadata.xml
new file mode 100644
index 0000000..b3df2bc
--- /dev/null
+++ b/dev-python/botocore/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>andrey_utkin@gentoo.org</email>
+		<name>Andrey Utkin</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">boto/botocore</remote-id>
+		<remote-id type="pypi">botocore</remote-id>
+	</upstream>
+</pkgmetadata>