sys-auth/elogind-219.12-r11 : Revision bump with additions and fixes from KDE overlay.

This is basically the new elogind-219.12-r3.ebuild from KDE overlay
with the following two changes:

1) The gperf dependency has been changed to =dev-util/gperf-3.0*,
   because it does not build using gperf-3.1

Note: This also happens with my current elogind-226 dev branch, which
      is using the exact build system as systemd-226.

2) /bin/ps is used during the start of openrc and fails, because
   libelogind.so.0 is not found if it was installed in /usr/lib* with
   /usr being on a separate partition. So the install goes into /lib*
   and pkgconfig is moved back to /usr/lib* by src_install().

Note: Later versions of elogind will support --with-rootlibdir which
      will render this manual move unnecessary.

4 files changed, 96 insertions, 135 deletions

diff --git a/profiles/package.mask/elogind b/profiles/package.mask/elogind
index 71192f7..d2971e3 100644
--- a/profiles/package.mask/elogind
+++ b/profiles/package.mask/elogind
@@ -10,7 +10,7 @@
 =sys-apps/accountsservice-0.6.43-r2
 =sys-apps/dbus-1.10.12-r1
 =sys-apps/dbus-1.10.14-r1
-=sys-auth/elogind-219.12-r9
+=sys-auth/elogind-219.12-r11
 =sys-auth/pambase-20150213-r2
 =sys-auth/polkit-0.113-r203
 =sys-fs/udisks-2.1.7-r4
diff --git a/sys-auth/elogind/elogind-219.12-r10.ebuild b/sys-auth/elogind/elogind-219.12-r10.ebuild
deleted file mode 100644
index fabf75d..0000000
--- a/sys-auth/elogind/elogind-219.12-r10.ebuild
+++ /dev/null
@@ -1,134 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=6
-
-inherit autotools eutils linux-info pam udev
-
-DESCRIPTION="The systemd project's logind, extracted to a standalone package"
-HOMEPAGE="https://github.com/wingo/elogind"
-SRC_URI="https://github.com/wingo/elogind/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="CC0-1.0 LGPL-2.1+ public-domain"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux"
-IUSE="acl apparmor pam policykit selinux +seccomp"
-
-COMMON_DEPEND="
-	sys-libs/libcap
-	sys-apps/util-linux
-	virtual/libudev:=
-	acl? ( sys-apps/acl )
-	apparmor? ( sys-libs/libapparmor )
-	pam? ( virtual/pam )
-	seccomp? ( sys-libs/libseccomp )
-	selinux? ( sys-libs/libselinux )
-"
-RDEPEND="${COMMON_DEPEND}
-	sys-apps/dbus
-	policykit? ( sys-auth/polkit )
-	!sys-auth/systemd
-"
-DEPEND="${COMMON_DEPEND}
-	dev-util/gperf
-	dev-util/intltool
-	sys-devel/libtool
-	virtual/pkgconfig
-"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-docs.patch"
-	"${FILESDIR}/${PN}-lrt.patch"
-	"${FILESDIR}/${P}-session.patch"
-	"${FILESDIR}/${PN}-add_missing_login1_permissions.patch"
-)
-
-pkg_setup() {
-	if use kernel_linux; then
-		linux-info_pkg_setup
-		if ! linux_config_exists; then
-			ewarn "Can't check the linux kernel configuration."
-		else
-			local missing_count=0
-			if ! linux_chkconfig_present CGROUPS; then
-				eerror "CGROUPS is not enabled but needed by elogind."
-				eerror " (it is OK to disable all controllers)"
-				missing_count=$((missing_count+1))
-			fi
-			if ! linux_chkconfig_present INOTIFY_USER; then
-				eerror "INOTIFY_USER is not enabled but needed by elogind."
-				missing_count=$((missing_count+1))
-			fi
-			if ! linux_chkconfig_present SIGNALFD; then
-				eerror "SIGNALFD is not enabled but needed by elogind."
-				missing_count=$((missing_count+1))
-			fi
-			if ! linux_chkconfig_present TIMERFD; then
-				eerror "TIMERFD is not enabled but needed by elogind."
-				missing_count=$((missing_count+1))
-			fi
-			if ! linux_chkconfig_present EPOLL; then
-				eerror "EPOLL is not enabled but needed by elogind."
-				missing_count=$((missing_count+1))
-			fi
-			if ! linux_chkconfig_present SECCOMP; then
-				einfo "SECCOMP is not enabled but useful to elogind."
-			fi
-			[ 0 -lt $missing_count ] && die "$missing_count required kernel features are missing."
-		fi
-	fi
-}
-
-src_prepare() {
-	default
-
-	# Makefile.am is patched by
-	# - "${FILESDIR}/${PN}-docs.patch"
-	# - "${FILESDIR}/${PN}-lrt.patch"
-	eautoreconf
-}
-
-src_configure() {
-	local use_smack="--disable-smack"
-	if linux_config_exists && linux_chkconfig_present SECURITY_SMACK; then
-		use_smack="--enable-smack"
-	fi
-
-	econf \
-		--with-pamlibdir=$(getpam_mod_dir) \
-		--with-udevrulesdir="$(get_udevdir)"/rules.d \
-		--libdir=/$(get_libdir) \
-		$(use_enable acl) \
-		$(use_enable apparmor) \
-		$(use_enable pam) \
-		$(use_enable seccomp) \
-		$(use_enable selinux) \
-		$use_smack
-}
-
-src_install() {
-	default
-
-	# Installation would fail with
-	# "static archives (*.a) and libtool library files
-	#  (*.la) belong in /usr/lib*, not /lib*"
-	# if we didn't prune them.
-	prune_libtool_files --modules
-
-	# Unfortunately the build system puts the pkgconfig file(s)
-	# into $(libdir)/pkgconfig - Move it to /usr/$(libdir)/pkgconfig
-	mkdir -p "${ED}"usr/$(get_libdir) || die
-	mv "${ED}"$(get_libdir)/pkgconfig "${ED}"usr/$(get_libdir)/ || die
-
-	newinitd "${FILESDIR}"/${PN}.init ${PN}
-	newconfd "${FILESDIR}"/${PN}.conf ${PN}
-}
-
-pkg_postinst() {
-	if [ "$(rc-config list default | grep elogind)" = "" ]; then
-		ewarn "To enable the elogind daemon, elogind must be"
-		ewarn "added to the default runlevel:"
-		ewarn "# rc-update add elogind default"
-	fi
-}
diff --git a/sys-auth/elogind/elogind-219.12-r11.ebuild b/sys-auth/elogind/elogind-219.12-r11.ebuild
new file mode 100644
index 0000000..e7b1552
--- /dev/null
+++ b/sys-auth/elogind/elogind-219.12-r11.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools linux-info pam udev
+
+DESCRIPTION="The systemd project's logind, extracted to a standalone package"
+HOMEPAGE="https://github.com/wingo/elogind"
+SRC_URI="https://github.com/wingo/elogind/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC0-1.0 LGPL-2.1+ public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="acl apparmor pam policykit selinux +seccomp"
+
+COMMON_DEPEND="
+	sys-libs/libcap
+	sys-apps/util-linux
+	virtual/libudev:=
+	acl? ( sys-apps/acl )
+	apparmor? ( sys-libs/libapparmor )
+	pam? ( virtual/pam )
+	seccomp? ( sys-libs/libseccomp )
+	selinux? ( sys-libs/libselinux )
+"
+RDEPEND="${COMMON_DEPEND}
+	sys-apps/dbus
+	policykit? ( sys-auth/polkit )
+	!sys-auth/systemd
+"
+DEPEND="${COMMON_DEPEND}
+	=dev-util/gperf-3.0*
+	dev-util/intltool
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-docs.patch"
+	"${FILESDIR}/${PN}-lrt.patch"
+	"${FILESDIR}/${P}-session.patch"
+	"${FILESDIR}/${P}-login1-perms.patch"
+)
+
+pkg_setup() {
+	local CONFIG_CHECK="~CGROUPS ~EPOLL ~INOTIFY_USER ~SECURITY_SMACK
+		~SIGNALFD ~TIMERFD"
+
+	use seccomp && CONFIG_CHECK+=" ~SECCOMP"
+
+	if use kernel_linux; then
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf # Makefile.am patched by "${FILESDIR}/${PN}-{docs,lrt}.patch"
+}
+
+src_configure() {
+	econf \
+		--with-pamlibdir=$(getpam_mod_dir) \
+		--with-udevrulesdir="$(get_udevdir)"/rules.d \
+		--libdir="${EPREFIX}"/$(get_libdir) \
+		--enable-smack \
+		$(use_enable acl) \
+		$(use_enable apparmor) \
+		$(use_enable pam) \
+		$(use_enable seccomp) \
+		$(use_enable selinux)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	# Unfortunately the build system puts the pkgconfig file(s)
+	# into $(libdir)/pkgconfig - Move it to /usr/$(libdir)/pkgconfig
+	mkdir -p "${ED%/}"/usr/$(get_libdir) || die
+	mv "${ED%/}"/$(get_libdir)/pkgconfig "${ED%/}"/usr/$(get_libdir)/ || die
+
+	newinitd "${FILESDIR}"/${PN}.init ${PN}
+	newconfd "${FILESDIR}"/${PN}.conf ${PN}
+}
+
+pkg_postinst() {
+	if [ "$(rc-config list default | grep elogind)" = "" ]; then
+		ewarn "To enable the elogind daemon, elogind must be"
+		ewarn "added to the default runlevel:"
+		ewarn "# rc-update add elogind default"
+	fi
+}
diff --git a/sys-auth/elogind/files/elogind-add_missing_login1_permissions.patch b/sys-auth/elogind/files/elogind-219.12-login1-perms.patch
index eecf38e..eecf38e 100644
--- a/sys-auth/elogind/files/elogind-add_missing_login1_permissions.patch
+++ b/sys-auth/elogind/files/elogind-219.12-login1-perms.patch