1 files changed, 60 insertions, 0 deletions
diff --git a/dev-python/flask/flask-0.10.1-r2.ebuild b/dev-python/flask/flask-0.10.1-r2.ebuild
new file mode 100644
index 0000000..f2d94b8
--- /dev/null
+++ b/dev-python/flask/flask-0.10.1-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+HOMEPAGE="https://github.com/mitsuhiko/flask/"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+IUSE="doc examples"
+
+RDEPEND="
+	dev-python/blinker[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-0.21[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.4[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.7[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+BDEPEND="${RDEPEND}"
+# Usual; test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-is_package.patch
+	"${FILESDIR}"/${P}-sort_json.patch
+	"${FILESDIR}"/${P}-test_appcontext.patch
+)
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "s/ 'sphinx.ext.intersphinx',//" -i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	"${PYTHON}" run-tests.py || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( examples/. )
+	use doc && HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}