1 files changed, 0 insertions, 58 deletions
diff --git a/app-eselect/eselect-repository/eselect-repository-13.ebuild b/app-eselect/eselect-repository/eselect-repository-13.ebuild
deleted file mode 100644
index 4bbaed00f1d7..000000000000
--- a/app-eselect/eselect-repository/eselect-repository-13.ebuild
+++ /dev/null
@@ -1,58 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..12} )
-inherit python-single-r1
-
-DESCRIPTION="Manage repos.conf via eselect"
-HOMEPAGE="https://github.com/projg2/eselect-repository/"
-SRC_URI="
-	https://github.com/projg2/eselect-repository/archive/v${PV}.tar.gz
-		-> ${P}.tar.gz
-"
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~arm64-macos ~x64-macos"
-IUSE="test"
-RESTRICT="!test? ( test )"
-REQUIRED_USE=${PYTHON_REQUIRED_USE}
-
-RDEPEND="
-	${PYTHON_DEPS}
-	app-admin/eselect
-	$(python_gen_cond_dep '
-		dev-python/lxml[${PYTHON_USEDEP}]
-	')
-	net-misc/wget
-"
-BDEPEND="
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/pytest[${PYTHON_USEDEP}]
-		')
-	)
-"
-
-src_compile() {
-	MAKEARGS=(
-		PREFIX="${EPREFIX}/usr"
-		SYSCONFDIR="${EPREFIX}/etc"
-		SHAREDSTATEDIR="${EPREFIX}/var"
-		ESELECTDIR="${EPREFIX}/usr/share/eselect/modules"
-	)
-
-	emake "${MAKEARGS[@]}"
-	python_fix_shebang eselect-repo-helper
-}
-
-src_test() {
-	epytest
-}
-
-src_install() {
-	emake "${MAKEARGS[@]}" DESTDIR="${D}" install
-	einstalldocs
-}