1 files changed, 37 insertions, 0 deletions
diff --git a/dev-ruby/erb/erb-4.0.3.ebuild b/dev-ruby/erb/erb-4.0.3.ebuild
new file mode 100644
index 00000000..ec1f7572
--- /dev/null
+++ b/dev-ruby/erb/erb-4.0.3.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32"
+
+# There is an erb binary in exe but that would conflict with the ruby
+# built-in version.
+RUBY_FAKEGEM_BINWRAP=""
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/erb/escape/extconf.rb)
+RUBY_FAKEGEM_EXTENSION_LIBDIR="lib/erb"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+RUBY_FAKEGEM_GEMSPEC="erb.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="An easy to use but powerful templating system for Ruby"
+HOMEPAGE="https://github.com/ruby/erb"
+SRC_URI="https://github.com/ruby/erb/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( Ruby-BSD BSD-2 )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+SLOT="0"
+IUSE="test"
+
+ruby_add_rdepend ">=dev-ruby/cgi-0.3.3"
+
+all_ruby_prepare() {
+	sed -e "s:_relative ': './:" \
+		-e 's/git ls-files -z/find * -print0/' \
+		-i ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:test:. -rtest/lib/helper -e "Dir['test/**/test_*.rb'].each { require _1 }" || die
+}