1 files changed, 42 insertions, 0 deletions
diff --git a/dev-ruby/inky-rb/inky-rb-1.4.2.1.ebuild b/dev-ruby/inky-rb/inky-rb-1.4.2.1.ebuild
new file mode 100644
index 00000000..2490f6f6
--- /dev/null
+++ b/dev-ruby/inky-rb/inky-rb-1.4.2.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby30 ruby31 ruby32"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A templating language that converts simple HTML into responsive email-ready HTML"
+HOMEPAGE="https://github.com/foundation/inky-rb"
+LICENSE="MIT"
+
+KEYWORDS="~amd64"
+SLOT="1"
+IUSE=""
+
+ruby_add_rdepend "
+	dev-ruby/foundation_emails:2
+	dev-ruby/nokogiri
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/bundler
+	dev-ruby/capybara
+	dev-ruby/rails
+	dev-ruby/rspec-rails
+)"
+
+all_ruby_prepare() {
+	rm -f Gemfile.lock || die
+	sed -i -e '/rubocop/I s:^:#:' -e '/bundler/I s:^:#:' Rakefile || die
+	sed -i -e '/rubocop/ s:^:#:' inky.gemspec || die
+
+	# Avoid tests depending on old versions of slim
+	sed -e '/when configured to use a different template engine/ s/context/xcontext/' \
+		-e '/(like slim)/ s/it/xit/' \
+		-i spec/test_app/spec/features/inky_spec.rb || die
+}