blob: 817ab8c5fdd09fdfda51a42452ba076ce8cb6e1a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
USE_RUBY="ruby25 ruby26 ruby27"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md SUPPORT.md"
RUBY_FAKEGEM_RECIPE_TEST="rspec3"
RUBY_FAKEGEM_EXTRAINSTALL="ext resources"
RUBY_FAKEGEM_EXTENSIONS=(ext/extconf.rb)
AGENT_VERSION=75e76ad
inherit ruby-fakegem
DESCRIPTION="The official appsignal.com gem"
HOMEPAGE="https://docs.appsignal.com/ruby/"
SRC_URI="https://rubygems.org/gems/appsignal-${PV}.gem https://appsignal-agent-releases.global.ssl.fastly.net/${AGENT_VERSION}/appsignal-x86_64-linux-all-static.tar.gz -> appsignal-x86_64-${PV}.patch.bz2"
LICENSE="MIT"
SLOT="$(ver_cut 1)"
KEYWORDS="~amd64"
IUSE="test"
ruby_add_rdepend "
dev-ruby/rack:*
!<dev-ruby/appsignal-2.11.9-r1:2
"
ruby_add_bdepend "test? (
dev-ruby/bundler
dev-ruby/timecop
dev-ruby/webmock
)"
all_ruby_prepare() {
sed -i -e '/rake/ s/~>/>=/' -e '/\("rubocop\|pry\)/ s:^:#:' appsignal.gemspec || die
sed -i -e '/pry/ s:^:#:' spec/spec_helper.rb || die
echo 'gem "json"' >> Gemfile || die
# This is a horrible hack to work around the default unpack support
# in all_ruby_unpack which tries to unpack all files in ${A} and
# then fails. But it leaves a patch.bz2 file untouched...
pushd ext || die
cp "${DISTDIR}/appsignal-x86_64-${PV}.patch.bz2" appsignal-x86_64-linux-all-static.tar.gz || die
popd || die
sed -i -e 's/download_archive(library_type)/open("appsignal-x86_64-linux-all-static.tar.gz")/' ext/extconf.rb || die
# Avoid specs that require a network
sed -i -e '/\(the\|extension\) installation report/askip "requires live network"' spec/lib/appsignal/cli/diagnose_spec.rb || die
}
each_ruby_test() {
${RUBY} -S bundle exec rspec-3 spec || die
}
each_ruby_install() {
each_fakegem_install
local extdir
extdir="$(ruby_fakegem_gemsdir)/gems/${RUBY_FAKEGEM_NAME}-${RUBY_FAKEGEM_VERSION}/ext"
fperms 0755 "${extdir}/appsignal-agent"
}
|
GitWeb
