1 files changed, 64 insertions, 0 deletions
diff --git a/media-gfx/hugin/hugin-2011.0.0_rc1.ebuild b/media-gfx/hugin/hugin-2011.0.0_rc1.ebuild
new file mode 100644
index 0000000..f2a8eca
--- /dev/null
+++ b/media-gfx/hugin/hugin-2011.0.0_rc1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/hugin-2010.4.0.ebuild,v 1.2 2011/02/13 11:03:32 radhermit Exp $
+
+EAPI=2
+WX_GTK_VER="2.8"
+
+inherit cmake-utils wxwidgets versionator
+
+DESCRIPTION="GUI for the creation & processing of panoramic images"
+HOMEPAGE="http://hugin.sf.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+LICENSE="GPL-2 SIFT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+LANGS=" bg ca cs de en_GB es fi fr hu it ja ko nl pl pt_BR ro ru sk sl sv uk zh_CN zh_TW"
+IUSE="lapack sift $(echo ${LANGS//\ /\ linguas_})"
+
+CDEPEND="
+	!!dev-util/cocom
+	app-arch/zip
+	>=dev-libs/boost-1.35.0-r5
+	>=media-gfx/enblend-4.0
+	media-gfx/exiv2
+	media-libs/freeglut
+	>=media-libs/libpano13-2.9.18
+	media-libs/libpng
+	media-libs/openexr
+	media-libs/tiff
+	sys-libs/zlib
+	virtual/jpeg
+	x11-libs/wxGTK:2.8[X,opengl,-odbc]
+	lapack? ( virtual/lapack )
+	sift? ( media-gfx/autopano-sift-C )"
+RDEPEND="${CDEPEND}
+	media-libs/exiftool"
+DEPEND="${CDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${PN}-$(get_version_component_range 1-3)
+
+pkg_setup() {
+	DOCS="authors.txt README TODO"
+	mycmakeargs=( $(cmake-utils_use_enable lapack LAPACK) )
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	for lang in ${LANGS} ; do
+		case ${lang} in
+			ca) dir=ca_ES;;
+			cs) dir=cs_CZ;;
+			*) dir=${lang};;
+		esac
+		use linguas_${lang} || rm -r "${D}"/usr/share/locale/${dir}
+	done
+}
+
+pkg_postinst() {
+	elog "Please note that the sift USE-flag has been disabled by default"
+	elog "as hugin ships its own control point generator with 2010.4"
+}