1 files changed, 54 insertions, 0 deletions
diff --git a/dev-python/traits/traits-4.0.0.ebuild b/dev-python/traits/traits-4.0.0.ebuild
new file mode 100644
index 0000000..c0de41f
--- /dev/null
+++ b/dev-python/traits/traits-4.0.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/traits/traits-4.0.0.ebuild,v 1.2 2011/08/04 00:05:56 bicatali Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.* *-jython"
+DISTUTILS_SRC_TEST="nosetests"
+
+inherit distutils
+
+DESCRIPTION="Enthought Tool Suite: Explicitly typed attributes for Python"
+HOMEPAGE="http://code.enthought.com/projects/traits/ http://pypi.python.org/pypi/traits"
+SRC_URI="http://www.enthought.com/repo/ETS/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/numpy"
+DEPEND="dev-python/setuptools
+	doc? ( dev-python/sphinx )
+	test? ( dev-python/numpy )"
+
+DOCS="docs/*.txt"
+
+src_compile() {
+	distutils_src_compile
+	if use doc; then
+		einfo "Generation of documentation"
+		pushd docs > /dev/null
+		emake html || die "Generation of documentation failed"
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	find -name "*LICENSE*.txt" -delete
+	distutils_src_install
+
+	if use doc; then
+		pushd docs/build/html > /dev/null
+		insinto /usr/share/doc/${PF}/html
+		doins -r [a-z]* _static || die "Installation of documentation failed"
+		popd > /dev/null
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples || die "Installation of examples failed"
+	fi
+}