kde-apps/print-manager: 21.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/kde-apps/print-manager/Manifest b/kde-apps/print-manager/Manifest
new file mode 100644
index 0000000000..a418a04ff5
--- /dev/null
+++ b/kde-apps/print-manager/Manifest
@@ -0,0 +1 @@
+DIST print-manager-21.04.0.tar.xz 259104 BLAKE2B 32e2324dd776f29928da16bd0ef95b72dc05c219b1d8c1be9e89f61566f0fd909e741efc621e10236c79b123faa82500609fd29d7b9aef84193dbb19c0c30d77 SHA512 3d3567111c28905e08748e864fda87b93cec2d2c42aedb996966c6cb8299ba1df32f4fbec7e3056c88bee5193f27fd1c70964c2e423602853da17bde34ce8d9a
diff --git a/kde-apps/print-manager/print-manager-21.04.0.ebuild b/kde-apps/print-manager/print-manager-21.04.0.ebuild
new file mode 100644
index 0000000000..04986407dc
--- /dev/null
+++ b/kde-apps/print-manager/print-manager-21.04.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.80.0
+PLASMA_MINIMAL=5.16.5
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Manage print jobs and printers in Plasma"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+gtk"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	net-print/cups
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PLASMA_MINIMAL}:5
+	gtk? ( app-admin/system-config-printer )
+"
+
+pkg_postinst(){
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! use gtk ; then
+		ewarn "By switching off \"gtk\" USE flag, you have chosen to do without"
+		ewarn "an important, though optional, runtime dependency:"
+		ewarn
+		ewarn "app-admin/system-config-printer"
+		ewarn
+		ewarn "${PN} will work nevertheless, but is going to be less comfortable"
+		ewarn "and will show the following error status during runtime:"
+		ewarn
+		ewarn "\"Failed to group devices: 'The name org.fedoraproject.Config.Printing"
+		ewarn "was not provided by any .service files'\""
+	fi
+}