kde-plasma: Add KDE Plasma 5.17 stable branch

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

48 files changed, 2404 insertions, 0 deletions

diff --git a/kde-plasma/bluedevil/bluedevil-5.17.49.9999.ebuild b/kde-plasma/bluedevil/bluedevil-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..84aae6c17c
--- /dev/null
+++ b/kde-plasma/bluedevil/bluedevil-5.17.49.9999.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="Bluetooth stack for KDE Plasma"
+HOMEPAGE="https://cgit.kde.org/bluedevil.git"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep bluez-qt)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kded)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep plasma)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+"
diff --git a/kde-plasma/breeze-grub/breeze-grub-5.17.49.9999.ebuild b/kde-plasma/breeze-grub/breeze-grub-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..b54e11cfc2
--- /dev/null
+++ b/kde-plasma/breeze-grub/breeze-grub-5.17.49.9999.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_AUTODEPS="false"
+KDE_DEBUG="false"
+inherit kde5
+
+DESCRIPTION="Breeze theme for GRUB"
+LICENSE="GPL-3+"
+KEYWORDS=""
+IUSE=""
+
+src_prepare() { default; }
+src_configure() { :; }
+src_compile() { :; }
+
+src_install() {
+	insinto /usr/share/grub/themes
+	doins -r breeze
+}
diff --git a/kde-plasma/breeze-gtk/breeze-gtk-5.17.49.9999.ebuild b/kde-plasma/breeze-gtk/breeze-gtk-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..3795a4e04c
--- /dev/null
+++ b/kde-plasma/breeze-gtk/breeze-gtk-5.17.49.9999.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+inherit kde5 python-any-r1
+
+DESCRIPTION="Official GTK+ port of Plasma's Breeze widget style"
+HOMEPAGE="https://cgit.kde.org/breeze-gtk.git"
+LICENSE="LGPL-2.1+"
+KEYWORDS=""
+IUSE=""
+
+BDEPEND="${PYTHON_DEPS}
+	$(add_plasma_dep breeze)
+	$(python_gen_any_dep 'dev-python/pycairo[${PYTHON_USEDEP}]')
+	dev-lang/sassc
+"
+
+python_check_deps() {
+	has_version "dev-python/pycairo[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+	kde5_pkg_setup
+}
diff --git a/kde-plasma/breeze-plymouth/breeze-plymouth-5.17.49.9999.ebuild b/kde-plasma/breeze-plymouth/breeze-plymouth-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..d299cbbf7f
--- /dev/null
+++ b/kde-plasma/breeze-plymouth/breeze-plymouth-5.17.49.9999.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_KDEINSTALLDIRS="false"
+KDE_AUTODEPS="false"
+inherit kde5
+
+DESCRIPTION="Breeze theme for Plymouth"
+LICENSE="GPL-2+ GPL-3+"
+KEYWORDS=""
+IUSE=""
+
+BDEPEND="$(add_frameworks_dep extra-cmake-modules)"
+DEPEND="sys-boot/plymouth"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISTRO_NAME="Gentoo Linux"
+		-DDISTRO_VERSION=
+	)
+
+	kde5_src_configure
+}
diff --git a/kde-plasma/breeze/breeze-5.17.49.9999.ebuild b/kde-plasma/breeze/breeze-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..ba59a80c19
--- /dev/null
+++ b/kde-plasma/breeze/breeze-5.17.49.9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="Breeze visual style for the Plasma desktop"
+HOMEPAGE="https://cgit.kde.org/breeze.git"
+KEYWORDS=""
+IUSE="wayland X"
+
+RDEPEND="
+	$(add_frameworks_dep frameworkintegration)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_plasma_dep kdecoration)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	sci-libs/fftw:3.0=
+	wayland? ( $(add_frameworks_dep kwayland) )
+	X? (
+		$(add_qt_dep qtx11extras)
+		x11-libs/libxcb
+	)
+"
+DEPEND="${RDEPEND}
+	$(add_frameworks_dep kpackage)
+"
+PDEPEND="
+	$(add_frameworks_dep breeze-icons)
+	$(add_plasma_dep kde-cli-tools)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package wayland KF5Wayland)
+		$(cmake-utils_use_find_package X XCB)
+	)
+	kde5_src_configure
+}
diff --git a/kde-plasma/discover/discover-5.17.49.9999.ebuild b/kde-plasma/discover/discover-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..1e3d615f81
--- /dev/null
+++ b/kde-plasma/discover/discover-5.17.49.9999.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE Plasma resources management GUI"
+HOMEPAGE="https://userbase.kde.org/Discover"
+KEYWORDS=""
+IUSE="+firmware"
+
+# libmarkdown (app-text/discount) only used in PackageKitBackend
+DEPEND="
+	$(add_frameworks_dep attica)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kirigami)
+	$(add_frameworks_dep kitemmodels)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtconcurrent)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	firmware? ( sys-apps/fwupd )
+"
+RDEPEND="${DEPEND}
+	$(add_frameworks_dep kirigami)
+"
+
+src_prepare() {
+	kde5_src_prepare
+	# we don't need it with PackageKitBackend off
+	punt_bogus_dep KF5 Archive
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_packagekitqt5=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_AppStreamQt=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Snapd=ON
+		-DBUILD_FlatpakBackend=OFF
+		-DBUILD_FwupdBackend=$(usex firmware)
+	)
+
+	kde5_src_configure
+}
+
+src_test() {
+	# bug 686392: needs network connection
+	local myctestargs=(
+		-E "(knsbackendtest)"
+	)
+
+	kde5_src_test
+}
diff --git a/kde-plasma/drkonqi/drkonqi-5.17.49.9999.ebuild b/kde-plasma/drkonqi/drkonqi-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..2bcdfe0d18
--- /dev/null
+++ b/kde-plasma/drkonqi/drkonqi-5.17.49.9999.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
+
+KEYWORDS=""
+IUSE="X"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kidletime)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwallet)
+	$(add_frameworks_dep kwayland)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlrpcclient)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	X? ( $(add_qt_dep qtx11extras) )
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_qt_dep qtconcurrent)
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/plasma-workspace-5.10.95:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package X Qt5X11Extras)
+	)
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+	if ! has_version "sys-devel/gdb"; then
+		elog "For more usability consider installing the following package:"
+		elog "    sys-devel/gdb - Easier debugging support"
+	fi
+}
diff --git a/kde-plasma/kactivitymanagerd/kactivitymanagerd-5.17.49.9999.ebuild b/kde-plasma/kactivitymanagerd/kactivitymanagerd-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..36e5f05a5e
--- /dev/null
+++ b/kde-plasma/kactivitymanagerd/kactivitymanagerd-5.17.49.9999.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="System service to manage user's activities, track the usage patterns etc."
+LICENSE="|| ( GPL-2 GPL-3 )"
+KEYWORDS=""
+IUSE=""
+
+RDEPEND="
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtsql 'sqlite')
+	$(add_qt_dep qtwidgets)
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
diff --git a/kde-plasma/kde-cli-tools/kde-cli-tools-5.17.49.9999.ebuild b/kde-plasma/kde-cli-tools/kde-cli-tools-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..757e81f84c
--- /dev/null
+++ b/kde-plasma/kde-cli-tools/kde-cli-tools-5.17.49.9999.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="optional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Tools based on KDE Frameworks 5 to better interact with the system"
+HOMEPAGE="https://cgit.kde.org/kde-cli-tools.git"
+KEYWORDS=""
+IUSE="kdesu X"
+
+REQUIRED_USE="kdesu? ( X )"
+
+DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_plasma_dep libkworkspace)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtsvg)
+	$(add_qt_dep qtwidgets)
+	kdesu? ( $(add_frameworks_dep kdesu) )
+	X? (
+		$(add_qt_dep qtx11extras)
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	kdesu? ( sys-apps/dbus[X] )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.12.80-tests-optional.patch" )
+
+# requires running kde environment
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package kdesu KF5Su)
+		$(cmake-utils_use_find_package X Qt5X11Extras)
+	)
+
+	kde5_src_configure
+}
+
+src_install() {
+	kde5_src_install
+	use kdesu && dosym ../$(get_libdir)/libexec/kf5/kdesu /usr/bin/kdesu
+}
diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.17.49.9999.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..ce3972e6b1
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.17.49.9999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE Plasma systemsettings kcm to set GTK application look&feel"
+HOMEPAGE="https://cgit.kde.org/kde-gtk-config.git"
+LICENSE="GPL-3"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtsvg)
+	$(add_qt_dep qtwidgets)
+	dev-libs/glib:2
+	gnome-base/gsettings-desktop-schemas
+	x11-libs/gtk+:2
+	x11-libs/gtk+:3
+	x11-libs/libXcursor
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+	elog "If you notice missing icons in your GTK applications, you may have to install"
+	elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+	elog "for example."
+}
diff --git a/kde-plasma/kdecoration/kdecoration-5.17.49.9999.ebuild b/kde-plasma/kdecoration/kdecoration-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..c005ecf253
--- /dev/null
+++ b/kde-plasma/kdecoration/kdecoration-5.17.49.9999.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Plugin based library to create window decorations"
+LICENSE="|| ( LGPL-2.1 LGPL-3 )"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep ki18n)
+	$(add_qt_dep qtgui)
+"
+RDEPEND="${DEPEND}"
diff --git a/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.17.49.9999.ebuild b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..a12b1a4fd0
--- /dev/null
+++ b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.17.49.9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="Extra Plasma applets and engines"
+LICENSE="GPL-2 LGPL-2"
+KEYWORDS=""
+IUSE="share webengine"
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kholidays)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep kross)
+	$(add_frameworks_dep krunner)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kunitconversion)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep plasma)
+	$(add_frameworks_dep sonnet)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	share? ( $(add_frameworks_dep purpose) )
+	webengine? ( $(add_qt_dep qtwebengine) )
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep plasma-workspace)
+	$(add_qt_dep qtquickcontrols)
+	$(add_qt_dep qtquickcontrols2)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package share KF5Purpose)
+		$(cmake-utils_use_find_package webengine Qt5WebEngine)
+	)
+
+	kde5_src_configure
+}
diff --git a/kde-plasma/kgamma/kgamma-5.17.49.9999.ebuild b/kde-plasma/kgamma/kgamma-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..0d706a7822
--- /dev/null
+++ b/kde-plasma/kgamma/kgamma-5.17.49.9999.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+KMNAME="${PN}5"
+inherit kde5
+
+DESCRIPTION="Screen gamma values kcontrol module"
+KEYWORDS=""
+IUSE=""
+
+RDEPEND="
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	x11-libs/libX11
+	x11-libs/libXxf86vm
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
diff --git a/kde-plasma/khotkeys/khotkeys-5.17.49.9999.ebuild b/kde-plasma/khotkeys/khotkeys-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..2ceab5d97d
--- /dev/null
+++ b/kde-plasma/khotkeys/khotkeys-5.17.49.9999.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional" # not optional until !kdelibs4support
+inherit kde5
+
+DESCRIPTION="KDE Plasma workspace hotkey module"
+KEYWORDS=""
+IUSE=""
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support X)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_plasma_dep libkworkspace)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtx11extras)
+	x11-libs/libX11
+	x11-libs/libXtst
+"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+	x11-libs/libxcb
+	x11-libs/libXtst
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kded)
+	$(add_plasma_dep kde-cli-tools)
+"
diff --git a/kde-plasma/kinfocenter/kinfocenter-5.17.49.9999.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..639463c3b5
--- /dev/null
+++ b/kde-plasma/kinfocenter/kinfocenter-5.17.49.9999.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MIN_VERSION=3.14.3
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="Utility providing information about the computer hardware"
+HOMEPAGE="https://kde.org/applications/system/kinfocenter/"
+SRC_URI+=" https://www.gentoo.org/assets/img/logo/gentoo-3d-small.png -> glogo-small.png"
+KEYWORDS=""
+IUSE="gles2 ieee1394 +opengl +pci wayland"
+
+REQUIRED_USE="wayland? ( || ( gles2 opengl ) )"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	x11-libs/libX11
+	ieee1394? ( sys-libs/libraw1394 )
+	opengl? (
+		$(add_qt_dep qtgui 'gles2=')
+		media-libs/mesa[gles2?,X(+)]
+		!gles2? ( media-libs/glu )
+	)
+	pci? ( sys-apps/pciutils )
+	wayland? (
+		$(add_frameworks_dep kwayland)
+		media-libs/mesa[egl]
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep plasma)
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+	$(add_qt_dep qtquickcontrols2)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package ieee1394 RAW1394)
+		$(cmake-utils_use_find_package pci PCIUTILS)
+		$(cmake-utils_use_find_package wayland EGL)
+		$(cmake-utils_use_find_package wayland KF5Wayland)
+	)
+
+	if has_version "dev-qt/qtgui[gles2]"; then
+		mycmakeargs+=( $(cmake-utils_use_find_package gles2 OpenGLES) )
+	else
+		mycmakeargs+=( $(cmake-utils_use_find_package opengl OpenGL) )
+	fi
+
+	kde5_src_configure
+}
+
+src_install() {
+	kde5_src_install
+
+	# TODO: Make this fully obsolete by /etc/os-release
+	insinto /etc/xdg
+	doins "${FILESDIR}"/kcm-about-distrorc
+
+	insinto /usr/share/${PN}
+	doins "${DISTDIR}"/glogo-small.png
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		has_version "net-fs/nfs-utils" || \
+			elog "Installing net-fs/nfs-utils will enable the NFS information module."
+
+		has_version "net-fs/samba" || \
+			elog "Installing net-fs/samba will enable the Samba status information module."
+	fi
+}
diff --git a/kde-plasma/kmenuedit/kmenuedit-5.17.49.9999.ebuild b/kde-plasma/kmenuedit/kmenuedit-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..5c91e681b8
--- /dev/null
+++ b/kde-plasma/kmenuedit/kmenuedit-5.17.49.9999.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="KDE Plasma menu editor"
+HOMEPAGE="https://cgit.kde.org/kmenuedit.git"
+KEYWORDS=""
+IUSE="+hotkeys"
+
+RDEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep sonnet)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	hotkeys? ( $(add_plasma_dep khotkeys) )
+"
+DEPEND="${RDEPEND}
+	$(add_frameworks_dep kinit)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package hotkeys KHotKeysDBusInterface)
+	)
+
+	kde5_src_configure
+}
diff --git a/kde-plasma/kscreen/kscreen-5.17.49.9999.ebuild b/kde-plasma/kscreen/kscreen-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..7620c1544b
--- /dev/null
+++ b/kde-plasma/kscreen/kscreen-5.17.49.9999.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="forceoptional"
+inherit kde5
+
+DESCRIPTION="KDE Plasma screen management"
+HOMEPAGE="https://cgit.kde.org/kscreen.git"
+
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep plasma)
+	$(add_plasma_dep libkscreen)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative 'widgets')
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+	$(add_qt_dep qtgraphicaleffects)
+"
+
+# bug #580440, last checked 5.6.3
+RESTRICT+=" test"
diff --git a/kde-plasma/kscreenlocker/kscreenlocker-5.17.49.9999.ebuild b/kde-plasma/kscreenlocker/kscreenlocker-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..43d0ebf072
--- /dev/null
+++ b/kde-plasma/kscreenlocker/kscreenlocker-5.17.49.9999.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5 pam
+
+DESCRIPTION="Library and components for secure lock screen architecture"
+KEYWORDS=""
+IUSE="consolekit +pam seccomp"
+
+REQUIRED_USE="seccomp? ( pam )"
+
+RDEPEND="
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kidletime)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwayland)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative 'widgets')
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtx11extras)
+	dev-libs/wayland
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-libs/libxcb
+	x11-libs/xcb-util-keysyms
+	consolekit? ( sys-auth/consolekit )
+	pam? ( virtual/pam )
+	seccomp? ( sys-libs/libseccomp )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+PDEPEND="
+	$(add_plasma_dep kde-cli-tools)
+"
+
+RESTRICT+=" test"
+
+src_prepare() {
+	kde5_src_prepare
+
+	if ! use test; then
+		sed -e "/add_subdirectory(autotests)/ s/^/#/" \
+			-i greeter/CMakeLists.txt || die
+	fi
+}
+
+src_test() {
+	# requires running environment
+	local myctestargs=(
+		-E x11LockerTest
+	)
+	kde5_src_test
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package consolekit loginctl)
+		-DPAM_REQUIRED=$(usex pam)
+		$(cmake-utils_use_find_package pam PAM)
+		$(cmake-utils_use_find_package seccomp Seccomp)
+	)
+	kde5_src_configure
+}
+
+src_install() {
+	kde5_src_install
+
+	use pam && newpamd "${FILESDIR}/kde.pam" kde
+	use pam && newpamd "${FILESDIR}/kde-np.pam" kde-np
+
+	if ! use pam; then
+		chown root "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
+		chmod +s "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
+	fi
+}
diff --git a/kde-plasma/ksshaskpass/ksshaskpass-5.17.49.9999.ebuild b/kde-plasma/ksshaskpass/ksshaskpass-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..5a545a4040
--- /dev/null
+++ b/kde-plasma/ksshaskpass/ksshaskpass-5.17.49.9999.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="KDE implementation of ssh-askpass with Kwallet integration"
+HOMEPAGE="https://cgit.kde.org/ksshaskpass.git"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kwallet)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}"
+
+src_install() {
+	kde5_src_install
+
+	insinto /etc/plasma/startup
+	doins "${FILESDIR}/05-ksshaskpass.sh"
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	elog ""
+	elog "In order to have ssh-agent start at kde startup,"
+	elog "edit /etc/plasma/startup/10-agent-startup.sh and uncomment"
+	elog "the lines enabling ssh-agent."
+	elog
+	elog "If you do so, do not forget to uncomment the respective"
+	elog "lines in /etc/plasma/shutdown/10-agent-shutdown.sh to"
+	elog "properly kill the agent when the session ends."
+	elog
+	elog "${PN} has been installed as your default askpass application"
+	elog "for Plasma 5 sessions."
+	elog "If that's not desired, select the one you want to use in"
+	elog "/etc/plasma/startup/05-ksshaskpass.sh"
+	elog ""
+}
diff --git a/kde-plasma/ksysguard/ksysguard-5.17.49.9999.ebuild b/kde-plasma/ksysguard/ksysguard-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..c2feefdcf7
--- /dev/null
+++ b/kde-plasma/ksysguard/ksysguard-5.17.49.9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="Network-enabled task manager and system monitor"
+LICENSE="GPL-2+"
+KEYWORDS=""
+IUSE="caps lm-sensors"
+
+DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kinit)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_plasma_dep libksysguard '-minimal(-)')
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	caps? (
+		net-libs/libpcap
+		sys-libs/libcap
+	)
+	lm-sensors? ( sys-apps/lm-sensors:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package caps Libcap)
+		$(cmake-utils_use_find_package lm-sensors Sensors)
+	)
+
+	kde5_src_configure
+}
diff --git a/kde-plasma/kwallet-pam/kwallet-pam-5.17.49.9999.ebuild b/kde-plasma/kwallet-pam/kwallet-pam-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..6c7b6bb822
--- /dev/null
+++ b/kde-plasma/kwallet-pam/kwallet-pam-5.17.49.9999.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="KWallet PAM module to not enter password again"
+LICENSE="LGPL-2.1"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kwallet)
+	dev-libs/libgcrypt:0=
+	virtual/pam
+"
+RDEPEND="${DEPEND}
+	net-misc/socat
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_LIBDIR="/$(get_libdir)"
+	)
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+	elog "This package enables auto-unlocking of kde-frameworks/kwallet:5."
+	elog "See also: https://wiki.gentoo.org/wiki/KDE#KWallet_auto-unlocking"
+}
diff --git a/kde-plasma/kwayland-integration/kwayland-integration-5.17.49.9999.ebuild b/kde-plasma/kwayland-integration/kwayland-integration-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..fb7276075e
--- /dev/null
+++ b/kde-plasma/kwayland-integration/kwayland-integration-5.17.49.9999.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="Provides integration plugins for various KDE frameworks for Wayland"
+HOMEPAGE="https://cgit.kde.org/kwayland-integration.git"
+
+LICENSE="LGPL-2.1"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep kidletime)
+	$(add_frameworks_dep kwayland)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT+=" test" # bug 668872
diff --git a/kde-plasma/kwin/kwin-5.17.49.9999.ebuild b/kde-plasma/kwin/kwin-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..7616348f29
--- /dev/null
+++ b/kde-plasma/kwin/kwin-5.17.49.9999.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="optional"
+KDE_TEST="optional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Flexible, composited Window Manager for windowing systems on Linux"
+LICENSE="GPL-2+"
+KEYWORDS=""
+IUSE="caps gles2 multimedia"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kglobalaccel '' '' '5=')
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kidletime '' '' '5=')
+	$(add_frameworks_dep kinit)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwayland)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem X)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep plasma)
+	$(add_plasma_dep breeze)
+	$(add_plasma_dep kdecoration)
+	$(add_plasma_dep kscreenlocker)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui 'gles2=' '' '5=')
+	$(add_qt_dep qtscript)
+	$(add_qt_dep qtsensors)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtx11extras)
+	>=dev-libs/libinput-1.9
+	>=dev-libs/wayland-1.2
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/libepoxy
+	media-libs/mesa[egl,gbm,gles2?,wayland,X(+)]
+	virtual/libudev:=
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-libs/libdrm
+	>=x11-libs/libxcb-1.10
+	>=x11-libs/libxkbcommon-0.7.0
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-keysyms
+	x11-libs/xcb-util-wm
+	caps? ( sys-libs/libcap )
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kirigami)
+	$(add_qt_dep qtquickcontrols)
+	$(add_qt_dep qtquickcontrols2)
+	$(add_qt_dep qtvirtualkeyboard)
+	multimedia? ( $(add_qt_dep qtmultimedia 'gstreamer,qml') )
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_qt_dep designer)
+	$(add_qt_dep qtconcurrent)
+	x11-base/xorg-proto
+"
+PDEPEND="
+	$(add_plasma_dep kde-cli-tools)
+"
+
+RESTRICT+=" test"
+
+src_prepare() {
+	kde5_src_prepare
+	use multimedia || eapply "${FILESDIR}/${PN}-5.16.80-gstreamer-optional.patch"
+
+	# Access violations, bug #640432
+	sed -e "s/^ecm_find_qmlmodule.*QtMultimedia/#&/" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package caps Libcap)
+	)
+
+	kde5_src_configure
+}
diff --git a/kde-plasma/kwrited/kwrited-5.17.49.9999.ebuild b/kde-plasma/kwrited/kwrited-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..2d5d2f68b4
--- /dev/null
+++ b/kde-plasma/kwrited/kwrited-5.17.49.9999.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="KDE Plasma daemon listening for wall and write messages"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kpty)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}"
diff --git a/kde-plasma/libkscreen/libkscreen-5.17.49.9999.ebuild b/kde-plasma/libkscreen/libkscreen-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..b4fe0f4ea8
--- /dev/null
+++ b/kde-plasma/libkscreen/libkscreen-5.17.49.9999.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_QTHELP="true"
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Plasma screen management library"
+SLOT="5/7"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kwayland)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtx11extras)
+	x11-libs/libxcb
+"
+RDEPEND="${DEPEND}"
+
+# requires running session
+RESTRICT+=" test"
diff --git a/kde-plasma/libksysguard/libksysguard-5.17.49.9999.ebuild b/kde-plasma/libksysguard/libksysguard-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..f7ef3e4408
--- /dev/null
+++ b/kde-plasma/libksysguard/libksysguard-5.17.49.9999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Task management and system monitoring library"
+LICENSE="LGPL-2+"
+KEYWORDS=""
+IUSE="minimal webengine X"
+
+RDEPEND="
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	sys-libs/zlib
+	webengine? ( $(add_qt_dep qtwebengine) )
+	X? (
+		$(add_qt_dep qtx11extras)
+		x11-libs/libX11
+		x11-libs/libXres
+	)
+"
+DEPEND="${RDEPEND}
+	$(add_frameworks_dep kiconthemes)
+	!minimal? ( $(add_frameworks_dep plasma) )
+	X? ( x11-base/xorg-proto )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.16.0-no-detailed-mem-message.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package !minimal KF5Plasma)
+		$(cmake-utils_use_find_package webengine Qt5WebEngineWidgets)
+		$(cmake-utils_use_find_package X X11)
+	)
+
+	kde5_src_configure
+}
diff --git a/kde-plasma/libkworkspace/libkworkspace-5.17.49.9999.ebuild b/kde-plasma/libkworkspace/libkworkspace-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..1282f6d256
--- /dev/null
+++ b/kde-plasma/libkworkspace/libkworkspace-5.17.49.9999.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="true"
+KMNAME="plasma-workspace"
+inherit kde5
+
+DESCRIPTION="Workspace library to interact with the Plasma session manager"
+
+KEYWORDS=""
+IUSE=""
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep plasma)
+	$(add_plasma_dep kscreenlocker)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtx11extras)
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_plasma_dep kwin)
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/plasma-workspace-5.14.2:5
+"
+
+S="${S}/${PN}"
+
+PATCHES=( "${FILESDIR}/${PN}-5.16.80-standalone.patch" )
+
+src_prepare() {
+	# delete colliding libkworkspace translations, let kde5_src_prepare do its magic
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find ../po -type f -name "*po" -and -not -name "libkworkspace*" -delete || die
+		rm -rf po/*/docs || die
+		cp -a ../po ./ || die
+	fi
+	kde5_src_prepare
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		cat >> CMakeLists.txt <<- _EOF_ || die
+			ki18n_install(po)
+		_EOF_
+	fi
+
+	sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" \
+		-i CMakeLists.txt || die "Failed to prepare CMakeLists.txt"
+}
diff --git a/kde-plasma/milou/milou-5.17.49.9999.ebuild b/kde-plasma/milou/milou-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..5e88de0042
--- /dev/null
+++ b/kde-plasma/milou/milou-5.17.49.9999.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="forceoptional-recursive"
+inherit kde5
+
+DESCRIPTION="Dedicated search application built on top of Baloo"
+HOMEPAGE="https://cgit.kde.org/milou.git"
+
+LICENSE="GPL-2 LGPL-2.1"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep krunner)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep plasma)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}"
diff --git a/kde-plasma/oxygen/oxygen-5.17.49.9999.ebuild b/kde-plasma/oxygen/oxygen-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..0bf15fcf59
--- /dev/null
+++ b/kde-plasma/oxygen/oxygen-5.17.49.9999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="Oxygen visual style for the Plasma desktop"
+HOMEPAGE="https://cgit.kde.org/oxygen.git"
+KEYWORDS=""
+IUSE="wayland"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep frameworkintegration)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_plasma_dep kdecoration)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtx11extras)
+	x11-libs/libxcb
+	wayland? ( $(add_frameworks_dep kwayland) )
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kservice)
+"
+RDEPEND="${COMMON_DEPEND}
+	!<kde-plasma/plasma-desktop-5.16.80
+"
+PDEPEND="
+	$(add_plasma_dep kde-cli-tools)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package wayland KF5Wayland)
+	)
+	kde5_src_configure
+}
diff --git a/kde-plasma/plasma-browser-integration/plasma-browser-integration-5.17.49.9999.ebuild b/kde-plasma/plasma-browser-integration/plasma-browser-integration-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..6277a9e831
--- /dev/null
+++ b/kde-plasma/plasma-browser-integration/plasma-browser-integration-5.17.49.9999.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="Integrate Chrome/Firefox better into Plasma through browser extensions"
+
+LICENSE="GPL-3+"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep krunner)
+	$(add_frameworks_dep purpose)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DMOZILLA_DIR="${EPREFIX}/usr/$(get_libdir)/mozilla"
+	)
+
+	kde5_src_configure
+}
diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.17.49.9999.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..6cdd26b43b
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.17.49.9999.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE Plasma desktop"
+KEYWORDS=""
+IUSE="+fontconfig ibus +mouse scim +semantic-desktop touchpad"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep attica)
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kactivities-stats)
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcodecs)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kded)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep kemoticons)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemmodels)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep kpeople)
+	$(add_frameworks_dep krunner)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwallet)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep plasma)
+	$(add_frameworks_dep solid)
+	$(add_frameworks_dep sonnet)
+	$(add_plasma_dep kwin)
+	$(add_plasma_dep plasma-workspace)
+	$(add_qt_dep qtconcurrent)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtprintsupport)
+	$(add_qt_dep qtsql)
+	$(add_qt_dep qtsvg)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtx11extras)
+	$(add_qt_dep qtxml)
+	media-libs/phonon[qt5(+)]
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxcb[xkb]
+	x11-libs/libxkbfile
+	fontconfig? (
+		media-libs/fontconfig
+		media-libs/freetype
+		x11-libs/libXft
+		x11-libs/xcb-util-image
+	)
+	ibus? (
+		$(add_qt_dep qtx11extras)
+		app-i18n/ibus
+		dev-libs/glib:2
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+	scim? ( app-i18n/scim )
+	semantic-desktop? ( $(add_frameworks_dep baloo) )
+	touchpad? ( x11-drivers/xf86-input-synaptics )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	x11-base/xorg-proto
+	fontconfig? ( x11-libs/libXrender )
+	mouse? (
+		x11-drivers/xf86-input-evdev
+		x11-drivers/xf86-input-libinput
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kirigami)
+	$(add_frameworks_dep qqc2-desktop-style)
+	$(add_plasma_dep breeze)
+	$(add_plasma_dep kde-cli-tools)
+	$(add_plasma_dep oxygen)
+	$(add_qt_dep qtgraphicaleffects)
+	$(add_qt_dep qtquickcontrols2)
+	sys-apps/util-linux
+	x11-apps/setxkbmap
+	!<kde-plasma/kdeplasma-addons-5.15.80
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package fontconfig Fontconfig)
+		$(cmake-utils_use_find_package ibus IBus)
+		$(cmake-utils_use_find_package mouse Evdev)
+		$(cmake-utils_use_find_package mouse XorgLibinput)
+		$(cmake-utils_use_find_package scim SCIM)
+		$(cmake-utils_use_find_package semantic-desktop KF5Baloo)
+		$(cmake-utils_use_find_package touchpad Synaptics)
+	)
+
+	kde5_src_configure
+}
+
+src_test() {
+	# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
+	# needs D-Bus, bug #634166
+	local myctestargs=(
+		-j1
+		-E "(foldermodeltest|positionertest|test_kio_fonts)"
+	)
+
+	kde5_src_test
+}
diff --git a/kde-plasma/plasma-integration/plasma-integration-5.17.49.9999.ebuild b/kde-plasma/plasma-integration/plasma-integration-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..86626c0b75
--- /dev/null
+++ b/kde-plasma/plasma-integration/plasma-integration-5.17.49.9999.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Qt Platform Theme integration plugins for the Plasma workspaces"
+LICENSE="LGPL-2+"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kwayland)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_plasma_dep breeze)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui 'dbus' '' '5=')
+	$(add_qt_dep qtquickcontrols2)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtx11extras)
+	x11-libs/libXcursor
+	x11-libs/libxcb
+"
+RDEPEND="${DEPEND}
+	media-fonts/hack
+	media-fonts/noto
+"
+
+# requires running kde environment
+RESTRICT+=" test"
diff --git a/kde-plasma/plasma-meta/plasma-meta-5.17.49.9999.ebuild b/kde-plasma/plasma-meta/plasma-meta-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..b9a2ea16b7
--- /dev/null
+++ b/kde-plasma/plasma-meta/plasma-meta-5.17.49.9999.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Merge this to pull in all Plasma 5 packages"
+HOMEPAGE="https://kde.org/plasma-desktop"
+
+LICENSE="metapackage"
+SLOT="5"
+KEYWORDS=""
+IUSE="bluetooth +browser-integration consolekit crypt +desktop-portal discover
++display-manager elogind grub gtk +handbook +legacy-systray networkmanager pam
+plymouth +pm-utils pulseaudio qrcode +sddm sdk systemd +wallpapers"
+
+REQUIRED_USE="?? ( consolekit elogind systemd )"
+
+RDEPEND="
+	>=kde-plasma/breeze-${PV}:${SLOT}
+	>=kde-plasma/drkonqi-${PV}:${SLOT}
+	>=kde-plasma/kactivitymanagerd-${PV}:${SLOT}
+	>=kde-plasma/kde-cli-tools-${PV}:${SLOT}
+	>=kde-plasma/kdecoration-${PV}:${SLOT}
+	>=kde-plasma/kdeplasma-addons-${PV}:${SLOT}
+	>=kde-plasma/kgamma-${PV}:${SLOT}
+	>=kde-plasma/khotkeys-${PV}:${SLOT}
+	>=kde-plasma/kinfocenter-${PV}:${SLOT}
+	>=kde-plasma/kmenuedit-${PV}:${SLOT}
+	>=kde-plasma/kscreen-${PV}:${SLOT}
+	>=kde-plasma/kscreenlocker-${PV}:${SLOT}
+	>=kde-plasma/ksshaskpass-${PV}:${SLOT}
+	>=kde-plasma/ksysguard-${PV}:${SLOT}
+	>=kde-plasma/kwayland-integration-${PV}:${SLOT}
+	>=kde-plasma/kwin-${PV}:${SLOT}
+	>=kde-plasma/kwrited-${PV}:${SLOT}
+	>=kde-plasma/libkscreen-${PV}:${SLOT}
+	>=kde-plasma/libksysguard-${PV}:${SLOT}
+	>=kde-plasma/milou-${PV}:${SLOT}
+	>=kde-plasma/oxygen-${PV}:${SLOT}
+	>=kde-plasma/plasma-desktop-${PV}:${SLOT}
+	>=kde-plasma/plasma-integration-${PV}:${SLOT}
+	>=kde-plasma/plasma-workspace-${PV}:${SLOT}
+	>=kde-plasma/polkit-kde-agent-${PV}:${SLOT}
+	>=kde-plasma/powerdevil-${PV}:${SLOT}
+	>=kde-plasma/systemsettings-${PV}:${SLOT}
+	>=kde-plasma/user-manager-${PV}:${SLOT}
+	sys-apps/dbus[elogind?,systemd?]
+	sys-auth/polkit[elogind?,systemd?]
+	sys-fs/udisks:2[elogind?,systemd?]
+	bluetooth? ( >=kde-plasma/bluedevil-${PV}:${SLOT} )
+	browser-integration? ( >=kde-plasma/plasma-browser-integration-${PV}:${SLOT} )
+	consolekit? (
+		>=sys-auth/consolekit-1.0.1
+		pm-utils? ( sys-power/pm-utils )
+	)
+	crypt? ( >=kde-plasma/plasma-vault-${PV}:${SLOT} )
+	desktop-portal? ( >=kde-plasma/xdg-desktop-portal-kde-${PV}:${SLOT} )
+	discover? ( >=kde-plasma/discover-${PV}:${SLOT} )
+	display-manager? (
+		sddm? (
+			>=kde-plasma/sddm-kcm-${PV}:${SLOT}
+			x11-misc/sddm[consolekit?,elogind?,systemd?]
+		)
+		!sddm? ( x11-misc/lightdm )
+	)
+	grub? ( >=kde-plasma/breeze-grub-${PV}:${SLOT} )
+	gtk? (
+		>=kde-plasma/breeze-gtk-${PV}:${SLOT}
+		>=kde-plasma/kde-gtk-config-${PV}:${SLOT}
+	)
+	handbook? ( kde-apps/khelpcenter:5 )
+	legacy-systray? ( >=kde-plasma/xembed-sni-proxy-${PV}:${SLOT} )
+	networkmanager? (
+		>=kde-plasma/plasma-nm-${PV}:${SLOT}
+		net-misc/networkmanager[consolekit?,elogind?,systemd?]
+		qrcode? ( kde-frameworks/prison[qml] )
+	)
+	pam? (
+		>=kde-plasma/kwallet-pam-${PV}:${SLOT}
+		sys-auth/pambase[consolekit?,elogind?,systemd?]
+	)
+	plymouth? (
+		>=kde-plasma/breeze-plymouth-${PV}:${SLOT}
+		>=kde-plasma/plymouth-kcm-${PV}:${SLOT}
+	)
+	pulseaudio? ( >=kde-plasma/plasma-pa-${PV}:${SLOT} )
+	sdk? ( >=kde-plasma/plasma-sdk-${PV}:${SLOT} )
+	wallpapers? ( >=kde-plasma/plasma-workspace-wallpapers-${PV}:${SLOT} )
+"
+
+pkg_postinst() {
+	local i selected use_pkg_map=(
+		consolekit:sys-auth/consolekit
+		elogind:sys-auth/elogind
+		systemd:sys-apps/systemd
+	)
+	for i in ${use_pkg_map[@]}; do
+		use ${i%:*} && selected="${i%:*}"
+	done
+	for i in ${use_pkg_map[@]}; do
+		if ! use ${i%:*} && has_version ${i#*:}; then
+			ewarn "An existing installation of ${i#*:} was detected even though"
+			ewarn "${PN} was configured with USE ${selected} instead of ${i%:*}."
+			ewarn "There can only be one session manager at runtime, otherwise random issues"
+			ewarn "may occur. Please make sure USE ${i%:*} is nowhere enabled in make.conf"
+			ewarn "or package.use and remove ${i#*:} before raising bugs."
+			ewarn "For more information, visit https://wiki.gentoo.org/wiki/KDE"
+		fi
+	done
+}
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.17.49.9999.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..397e8f61dc
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.17.49.9999.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+LICENSE="GPL-2 LGPL-2.1"
+KEYWORDS=""
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwallet)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep networkmanager-qt 'teamd=')
+	$(add_frameworks_dep plasma)
+	$(add_frameworks_dep solid)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative 'widgets')
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	>=app-crypt/qca-2.1.1:2[qt5(+)]
+	net-misc/networkmanager[teamd=]
+	modemmanager? (
+		$(add_frameworks_dep modemmanager-qt)
+		$(add_qt_dep qtxml)
+		net-misc/mobile-broadband-provider-info
+	)
+	openconnect? (
+		$(add_qt_dep qtxml)
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
+		$(cmake-utils_use_find_package modemmanager KF5ModemManagerQt)
+		$(cmake-utils_use_find_package openconnect OpenConnect)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	if ! has_version "kde-plasma/plasma-workspace:5"; then
+		elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell5 kcm_networkmanagement"
+	fi
+}
diff --git a/kde-plasma/plasma-pa/plasma-pa-5.17.49.9999.ebuild b/kde-plasma/plasma-pa/plasma-pa-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..b1d720e6af
--- /dev/null
+++ b/kde-plasma/plasma-pa/plasma-pa-5.17.49.9999.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="Plasma applet for audio volume management using PulseAudio"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep plasma)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	dev-libs/glib:2
+	media-libs/libcanberra
+	media-sound/pulseaudio
+"
+RDEPEND="${DEPEND}
+	$(add_frameworks_dep kirigami)
+	$(add_qt_dep qtquickcontrols2)
+	media-libs/libcanberra
+	x11-themes/sound-theme-freedesktop
+"
diff --git a/kde-plasma/plasma-sdk/plasma-sdk-5.17.49.9999.ebuild b/kde-plasma/plasma-sdk/plasma-sdk-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..3c52aa7948
--- /dev/null
+++ b/kde-plasma/plasma-sdk/plasma-sdk-5.17.49.9999.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="optional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Useful applications for Plasma development"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktexteditor)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep plasma)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+"
+RDEPEND="${DEPEND}
+	$(add_frameworks_dep kirigami)
+"
diff --git a/kde-plasma/plasma-thunderbolt/plasma-thunderbolt-5.17.49.9999.ebuild b/kde-plasma/plasma-thunderbolt/plasma-thunderbolt-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..6deb83a0a1
--- /dev/null
+++ b/kde-plasma/plasma-thunderbolt/plasma-thunderbolt-5.17.49.9999.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="Plasma integration for controlling Thunderbolt devices"
+HOMEPAGE="https://cgit.kde.org/plasma-thunderbolt.git"
+
+LICENSE="|| ( GPL-2 GPL-3+ )"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep knotifications)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+"
+RDEPEND="${DEPEND}
+	sys-apps/bolt
+"
diff --git a/kde-plasma/plasma-vault/plasma-vault-5.17.49.9999.ebuild b/kde-plasma/plasma-vault/plasma-vault-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..88e94dced5
--- /dev/null
+++ b/kde-plasma/plasma-vault/plasma-vault-5.17.49.9999.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="Plasma applet and services for creating encrypted vaults"
+HOMEPAGE+=" https://cukic.co/2017/02/03/vaults-encryption-in-plasma/"
+
+LICENSE="LGPL-3"
+KEYWORDS=""
+IUSE="networkmanager"
+
+DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kcodecs)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep plasma)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_plasma_dep libksysguard)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	networkmanager? ( $(add_frameworks_dep networkmanager-qt) )
+"
+RDEPEND="${DEPEND}
+	|| ( >=sys-fs/cryfs-0.9.9 >=sys-fs/encfs-1.9.2 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package networkmanager KF5NetworkManagerQt)
+	)
+
+	kde5_src_configure
+}
diff --git a/kde-plasma/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.17.49.9999.ebuild b/kde-plasma/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..243175d59e
--- /dev/null
+++ b/kde-plasma/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.17.49.9999.ebuild
@@ -0,0 +1,17 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_AUTODEPS="false"
+KDE_DEBUG="false"
+inherit kde5
+
+DESCRIPTION="Additional wallpapers for the Plasma workspace"
+KEYWORDS=""
+IUSE=""
+
+BDEPEND="
+	$(add_frameworks_dep extra-cmake-modules)
+	$(add_qt_dep qtcore)
+"
diff --git a/kde-plasma/plasma-workspace/plasma-workspace-5.17.49.9999.ebuild b/kde-plasma/plasma-workspace/plasma-workspace-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..d6b7b9c862
--- /dev/null
+++ b/kde-plasma/plasma-workspace/plasma-workspace-5.17.49.9999.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE Plasma workspace"
+KEYWORDS=""
+IUSE="appstream +calendar geolocation gps qalculate qrcode +semantic-desktop systemd"
+
+REQUIRED_USE="gps? ( geolocation )"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kactivities-stats)
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kded)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kidletime)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemmodels)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep kpeople)
+	$(add_frameworks_dep krunner)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktexteditor)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwallet)
+	$(add_frameworks_dep kwayland)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep plasma)
+	$(add_frameworks_dep solid)
+	$(add_plasma_dep kscreenlocker)
+	$(add_plasma_dep kwin)
+	$(add_plasma_dep libkscreen)
+	$(add_plasma_dep libksysguard)
+	$(add_plasma_dep libkworkspace)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative 'widgets')
+	$(add_qt_dep qtgui 'jpeg')
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtsql)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtx11extras)
+	$(add_qt_dep qtxml)
+	media-libs/phonon[qt5(+)]
+	sys-libs/zlib
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libxcb
+	x11-libs/libXfixes
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	appstream? ( dev-libs/appstream[qt5] )
+	calendar? ( $(add_frameworks_dep kholidays) )
+	geolocation? ( $(add_frameworks_dep networkmanager-qt) )
+	gps? ( sci-geosciences/gpsd )
+	qalculate? ( sci-libs/libqalculate:= )
+	qrcode? ( $(add_frameworks_dep prison) )
+	semantic-desktop? ( $(add_frameworks_dep baloo) )
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_qt_dep qtconcurrent)
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kdesu)
+	$(add_frameworks_dep kirigami)
+	$(add_kdeapps_dep kio-extras)
+	$(add_plasma_dep ksysguard)
+	$(add_plasma_dep milou)
+	$(add_plasma_dep plasma-integration)
+	$(add_qt_dep qdbus)
+	$(add_qt_dep qtgraphicaleffects)
+	$(add_qt_dep qtpaths)
+	$(add_qt_dep qtquickcontrols 'widgets')
+	$(add_qt_dep qtquickcontrols2)
+	app-text/iso-codes
+	x11-apps/xmessage
+	x11-apps/xprop
+	x11-apps/xrdb
+	x11-apps/xsetroot
+	systemd? ( sys-apps/dbus[user-session] )
+	!systemd? ( sys-apps/dbus )
+	!<kde-plasma/plasma-desktop-5.16.80:5
+"
+PDEPEND="
+	$(add_plasma_dep kde-cli-tools)
+"
+
+PATCHES=(
+	# TODO: Restore Gentoo part for FHS installs, bug 688366
+	"${FILESDIR}/${PN}-5.14.2-split-libkworkspace.patch"
+)
+
+RESTRICT+=" test"
+
+src_prepare() {
+	kde5_src_prepare
+
+	cmake_comment_add_subdirectory libkworkspace
+	# delete colliding libkworkspace translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_xembed-sni-proxy=OFF
+		$(cmake-utils_use_find_package appstream AppStreamQt)
+		$(cmake-utils_use_find_package calendar KF5Holidays)
+		$(cmake-utils_use_find_package geolocation KF5NetworkManagerQt)
+		$(cmake-utils_use_find_package qalculate Qalculate)
+		$(cmake-utils_use_find_package qrcode KF5Prison)
+		$(cmake-utils_use_find_package semantic-desktop KF5Baloo)
+	)
+
+	use gps && mycmakeargs+=( $(cmake-utils_use_find_package gps libgps) )
+
+	kde5_src_configure
+}
+
+src_install() {
+	kde5_src_install
+
+	# startup and shutdown scripts
+	insinto /etc/plasma/startup
+	doins "${FILESDIR}/10-agent-startup.sh"
+
+	insinto /etc/plasma/shutdown
+	doins "${FILESDIR}/10-agent-shutdown.sh"
+}
+
+pkg_postinst () {
+	kde5_pkg_postinst
+
+	elog "TODO: /etc/plasma/{startup,shutdown} locations for gpg-agent/ssh-agent"
+	elog "do not currently work, see bug #688366."
+}
diff --git a/kde-plasma/plymouth-kcm/plymouth-kcm-5.17.49.9999.ebuild b/kde-plasma/plymouth-kcm/plymouth-kcm-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..ac7bc90249
--- /dev/null
+++ b/kde-plasma/plymouth-kcm/plymouth-kcm-5.17.49.9999.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+BOGUS=1
+inherit kde5
+
+DESCRIPTION="KDE Plasma control module for Plymouth"
+HOMEPAGE="https://cgit.kde.org/plymouth-kcm.git"
+
+LICENSE="GPL-2+"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtquickcontrols)
+	$(add_qt_dep qtwidgets)
+	sys-boot/plymouth
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+"
+
+DOCS=( CONTRIBUTORS )
diff --git a/kde-plasma/polkit-kde-agent/polkit-kde-agent-5.17.49.9999.ebuild b/kde-plasma/polkit-kde-agent/polkit-kde-agent-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..fa6a565c62
--- /dev/null
+++ b/kde-plasma/polkit-kde-agent/polkit-kde-agent-5.17.49.9999.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KMNAME="${PN}-1"
+inherit kde5
+
+DESCRIPTION="PolKit agent module for KDE Plasma"
+HOMEPAGE="https://kde.org/"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	>=sys-auth/polkit-qt-0.112.0[qt5(+)]
+"
+RDEPEND="${DEPEND}"
diff --git a/kde-plasma/powerdevil/powerdevil-5.17.49.9999.ebuild b/kde-plasma/powerdevil/powerdevil-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..aea7e3cfd9
--- /dev/null
+++ b/kde-plasma/powerdevil/powerdevil-5.17.49.9999.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="Power management for KDE Plasma Shell"
+HOMEPAGE="https://cgit.kde.org/powerdevil.git"
+KEYWORDS=""
+IUSE="brightness-control +wireless"
+
+DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kauth policykit)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kidletime)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwayland)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_plasma_dep libkscreen)
+	$(add_plasma_dep libkworkspace)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtx11extras)
+	virtual/libudev:=
+	x11-libs/libxcb
+	brightness-control? ( app-misc/ddcutil )
+	wireless? (
+		$(add_frameworks_dep bluez-qt)
+		$(add_frameworks_dep networkmanager-qt)
+	)
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+	>=sys-power/upower-0.9.23
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_DDCUTIL=$(usex brightness-control)
+		$(cmake-utils_use_find_package wireless KF5BluezQt)
+		$(cmake-utils_use_find_package wireless KF5NetworkManagerQt)
+	)
+
+	kde5_src_configure
+}
diff --git a/kde-plasma/sddm-kcm/sddm-kcm-5.17.49.9999.ebuild b/kde-plasma/sddm-kcm/sddm-kcm-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..5bcb132053
--- /dev/null
+++ b/kde-plasma/sddm-kcm/sddm-kcm-5.17.49.9999.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="KDE Plasma control module for SDDM"
+HOMEPAGE="https://cgit.kde.org/sddm-kcm.git"
+
+LICENSE="GPL-2+"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtdeclarative 'widgets')
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}
+	$(add_plasma_dep kde-cli-tools)
+	x11-misc/sddm
+"
+
+DOCS=( CONTRIBUTORS )
diff --git a/kde-plasma/systemsettings/systemsettings-5.17.49.9999.ebuild b/kde-plasma/systemsettings/systemsettings-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..93eab16fcb
--- /dev/null
+++ b/kde-plasma/systemsettings/systemsettings-5.17.49.9999.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="Control Center to configure KDE Plasma desktop"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kactivities-stats)
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kpackage)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_plasma_dep libkworkspace)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtdeclarative 'widgets')
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}
+	$(add_frameworks_dep kirigami)
+"
+
+src_prepare() {
+	kde5_src_prepare
+
+	# FIXME: hangs in chroot; similar to bug #640432
+	sed -e "s/^ecm_find_qmlmodule.*org\.kde\.kcm/#&/" \
+		-i CMakeLists.txt || die
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		has_version kde-plasma/kde-gtk-config || \
+			elog "Install kde-plasma/kde-gtk-config to configure looks for GTK+."
+	fi
+}
diff --git a/kde-plasma/user-manager/user-manager-5.17.49.9999.ebuild b/kde-plasma/user-manager/user-manager-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..45e231692d
--- /dev/null
+++ b/kde-plasma/user-manager/user-manager-5.17.49.9999.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="Simple system settings module to manage the users of your system"
+KEYWORDS=""
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	>=dev-libs/libpwquality-1.3.0
+"
+RDEPEND="${DEPEND}
+	sys-apps/accountsservice
+"
diff --git a/kde-plasma/xdg-desktop-portal-kde/xdg-desktop-portal-kde-5.17.49.9999.ebuild b/kde-plasma/xdg-desktop-portal-kde/xdg-desktop-portal-kde-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..6b0a9c78e0
--- /dev/null
+++ b/kde-plasma/xdg-desktop-portal-kde/xdg-desktop-portal-kde-5.17.49.9999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Backend implementation for xdg-desktop-portal that is using Qt/KDE Frameworks"
+LICENSE="LGPL-2+"
+KEYWORDS=""
+IUSE="screencast"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtprintsupport 'cups')
+	$(add_qt_dep qtwidgets)
+	screencast? (
+		dev-libs/glib:2
+		media-libs/libepoxy
+		media-libs/mesa[gbm]
+		media-video/pipewire:=
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kwayland)
+	$(add_qt_dep qtconcurrent)
+"
+RDEPEND="${COMMON_DEPEND}
+	screencast? ( sys-apps/xdg-desktop-portal[screencast] )
+	!screencast? ( sys-apps/xdg-desktop-portal )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package screencast GLIB2)
+		$(cmake-utils_use_find_package screencast PipeWire)
+		$(cmake-utils_use_find_package screencast GBM)
+		$(cmake-utils_use_find_package screencast Epoxy)
+	)
+	kde5_src_configure
+}
diff --git a/kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.17.49.9999.ebuild b/kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.17.49.9999.ebuild
new file mode 100644
index 0000000000..ed07b2be85
--- /dev/null
+++ b/kde-plasma/xembed-sni-proxy/xembed-sni-proxy-5.17.49.9999.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_AUTODEPS="false"
+KMNAME="plasma-workspace"
+inherit kde5
+
+DESCRIPTION="Legacy xembed tray icons support for SNI-only system trays"
+HOMEPAGE="https://cgit.kde.org/plasma-workspace.git/tree/xembed-sni-proxy/Readme.md"
+
+LICENSE="GPL-2"
+KEYWORDS=""
+
+DEPEND="
+	$(add_frameworks_dep extra-cmake-modules)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_qt_dep qtcore)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtx11extras)
+	x11-libs/libxcb
+	x11-libs/libXtst
+	x11-libs/xcb-util-image
+"
+RDEPEND="${DEPEND}
+	!<kde-plasma/plasma-workspace-5.14.2:5
+	!kde-plasma/xembed-sni-proxy:0
+"
+
+S="${S}/${PN}"
+
+PATCHES=( "${FILESDIR}/${PN}-5.14.90-standalone.patch" )
+
+src_prepare() {
+	kde5_src_prepare
+
+	sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" \
+		-i CMakeLists.txt || die "Failed to prepare CMakeLists.txt"
+}