kde-frameworks: Add KDE Frameworks 5.65.0

Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/kde-frameworks/plasma/Manifest b/kde-frameworks/plasma/Manifest
new file mode 100644
index 0000000000..170777800a
--- /dev/null
+++ b/kde-frameworks/plasma/Manifest
@@ -0,0 +1 @@
+DIST plasma-framework-5.65.0.tar.xz 3123308 BLAKE2B a3094aeb3f5282b485b71d55353ac1f7b986567d48256dae785e55ce5f631a386fce2b47f56b20eaaccd82307437936b9a19ae08abd8f0ff6656cd80bf0fe003 SHA512 a8b3cd9921b759631d717af365ef64e34a9b00db9237a4c2f4006a15bcf12c3f34f4d19bef8b50aaaa7e47ceb8055617cfb0a1e76783d9287f03127df1241f85
diff --git a/kde-frameworks/plasma/plasma-5.65.0.ebuild b/kde-frameworks/plasma/plasma-5.65.0.ebuild
new file mode 100644
index 0000000000..2738194ffc
--- /dev/null
+++ b/kde-frameworks/plasma/plasma-5.65.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_ORG_NAME="${PN}-framework"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.12.3
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Plasma framework"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="gles2 wayland X"
+
+# drop qtgui subslot operator when QT_MINIMAL >= 5.14.0
+BDEPEND="
+	>=kde-frameworks/kdoctools-${PVCUT}:5
+"
+RDEPEND="
+	>=kde-frameworks/kactivities-${PVCUT}:5
+	>=kde-frameworks/karchive-${PVCUT}:5
+	>=kde-frameworks/kconfig-${PVCUT}:5
+	>=kde-frameworks/kconfigwidgets-${PVCUT}:5
+	>=kde-frameworks/kcoreaddons-${PVCUT}:5
+	>=kde-frameworks/kdeclarative-${PVCUT}:5
+	>=kde-frameworks/kglobalaccel-${PVCUT}:5
+	>=kde-frameworks/kguiaddons-${PVCUT}:5
+	>=kde-frameworks/ki18n-${PVCUT}:5
+	>=kde-frameworks/kiconthemes-${PVCUT}:5
+	>=kde-frameworks/kio-${PVCUT}:5
+	>=kde-frameworks/kirigami-${PVCUT}:5
+	>=kde-frameworks/knotifications-${PVCUT}:5
+	>=kde-frameworks/kpackage-${PVCUT}:5
+	>=kde-frameworks/kservice-${PVCUT}:5
+	>=kde-frameworks/kwidgetsaddons-${PVCUT}:5
+	>=kde-frameworks/kwindowsystem-${PVCUT}:5
+	>=kde-frameworks/kxmlgui-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5=[gles2=]
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	!gles2? ( virtual/opengl )
+	wayland? (
+		>=kde-frameworks/kwayland-${PVCUT}:5
+		media-libs/mesa[egl]
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libxcb
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package !gles2 OpenGL)
+		$(cmake_use_find_package wayland EGL)
+		$(cmake_use_find_package wayland KF5Wayland)
+		$(cmake_use_find_package X X11)
+		$(cmake_use_find_package X XCB)
+	)
+
+	ecm_src_configure
+}